001/src/life_time.erl

   1 -module(life_time).
   2 -behaviour(gen_server).
   3
   4
   5 %% API
   6 -export([start_link/3
   7         ,tock/2
   8         ]).
   9
  10 %% Callbacks
  11 -export([init/1
  12         ,handle_call/3
  13         ,handle_cast/2
  14         ,handle_info/2
  15         ,terminate/2
  16         ,code_change/3
  17         ]).
  18
  19
  20 -define(INTERVAL, 100).  % In milliseconds
  21
  22 -define(CHAR_DEAD,   32).  % Space
  23 -define(CHAR_ALIVE, 111).  % o
  24 -define(CHAR_BAR,    45).  % -
  25
  26
  27 -record(state, {x               :: integer()
  28                ,y               :: integer()
  29                ,cells           :: list(atom())
  30                ,num_cells       :: integer()
  31                ,state_pairs     :: list(tuple(integer(), integer())) | []
  32                ,replies_pending :: integer()
  33                ,generation = 0  :: integer()
  34                }).
  35
  36
  37 %% ============================================================================
  38 %% API
  39 %% ============================================================================
  40
  41 start_link(X, Y, Cells) ->
  42     ServerName = {local, ?MODULE},
  43     Args = [X, Y, Cells],
  44     Opts = [],
  45     gen_server:start_link(ServerName, ?MODULE, Args, Opts).
  46
  47
  48 tock(CellID, CellState) ->
  49     gen_server:cast(?MODULE, {tock, {CellID, CellState}}).
  50
  51
  52 %% ============================================================================
  53 %% Callbacks
  54 %% ============================================================================
  55
  56 init([X, Y, Cells]) ->
  57     State = #state{x=X
  58                   ,y=Y
  59                   ,cells=Cells
  60                   ,num_cells=length(Cells)
  61                   ,state_pairs=[]
  62                   ,replies_pending=0
  63                   },
  64     schedule_next_tick(),
  65     {ok, State}.
  66
  67
  68 terminate(_Reason, State) ->
  69     {ok, State}.
  70
  71
  72 code_change(_Old, State, _Other) ->
  73     {ok, State}.
  74
  75
  76 handle_call(_Msg, _From, State) ->
  77     {reply, ok, State}.
  78
  79
  80 handle_cast(next_tick,
  81     #state{cells=Cells
  82           ,num_cells=NumCells
  83           ,state_pairs=[]
  84           ,generation=Generation
  85           }=State) ->
  86
  87     NewGeneration = Generation + 1,
  88     ok = cast_all(Cells, {tick, NewGeneration}),
  89     {noreply, State#state{replies_pending=NumCells, generation=NewGeneration}};
  90
  91 handle_cast({tock, {ID, CellState}},
  92     #state{x=X
  93           ,y=Y
  94           ,state_pairs=StatePairs
  95           ,replies_pending=RepliesPending
  96           ,generation=Generation
  97           ,num_cells=NumCells
  98           }=State) ->
  99
 100     NewStatePairs = [{ID, CellState} | StatePairs],
 101     NewRepliesPending = RepliesPending - 1,
 102     NewState = State#state{replies_pending=NewRepliesPending},
 103
 104     case NewRepliesPending of
 105         0 ->
 106             SortedStatePairs = lists:sort(
 107                 fun({A, _}, {B, _}) -> A < B end,
 108                 NewStatePairs
 109             ),
 110             StateChars = [state_to_char(S) || {_, S} <- SortedStatePairs],
 111
 112             ok = io:format(
 113                 "X: ~b Y: ~b CELLS: ~b GENERATION: ~b~n",
 114                 [X, Y, NumCells, Generation]
 115             ),
 116             ok = do_print_bar(X),
 117
 118             ok = do_print_state_chars(X, StateChars),
 119
 120             ok = timer:sleep(?INTERVAL),
 121             schedule_next_tick(),
 122             {noreply, NewState#state{state_pairs=[]}};
 123
 124         _N ->
 125             {noreply, NewState#state{state_pairs=NewStatePairs}}
 126     end;
 127
 128 handle_cast(_Msg, State) ->
 129     {noreply, State}.
 130
 131
 132 handle_info(_Msg, State) ->
 133     {noreply, State}.
 134
 135
 136 %% ============================================================================
 137 %% Internal
 138 %% ============================================================================
 139
 140 schedule_next_tick() ->
 141     gen_server:cast(?MODULE, next_tick).
 142
 143
 144 cast_all([], _) -> ok;
 145 cast_all([Server | Servers], Msg) ->
 146     ok = gen_server:cast(Server, Msg),
 147     cast_all(Servers, Msg).
 148
 149
 150 state_to_char(0) -> ?CHAR_DEAD;
 151 state_to_char(1) -> ?CHAR_ALIVE.
 152
 153
 154 do_print_state_chars(_, []) -> ok;
 155 do_print_state_chars(X, Chars) ->
 156     {XChars, RestChars} = lists:split(X, Chars),
 157     ok = io:format([XChars, $\n]),
 158     do_print_state_chars(X, RestChars).
 159
 160
 161 do_print_bar(X) ->
 162     io:format("~s~n", [[?CHAR_BAR || _ <- lists:seq(1, X - 1)]]).