001/src/life_time.erl

   1 -module(life_time).
   2 -behaviour(gen_server).
   3
   4
   5 %% API
   6 -export([start_link/3
   7         ,report_state/3
   8         ]).
   9
  10 %% Callbacks
  11 -export([init/1
  12         ,handle_call/3
  13         ,handle_cast/2
  14         ,handle_info/2
  15         ,terminate/2
  16         ,code_change/3
  17         ]).
  18
  19
  20 -define(INTERVAL, 100).  % In milliseconds
  21
  22 -define(CHAR_DEAD,   32).  % " "
  23 -define(CHAR_ALIVE, 111).  % "o"
  24 -define(CHAR_BAR,    45).  % "-"
  25
  26
  27 -record(state, {x               :: integer()
  28                ,y               :: integer()
  29                ,cells           :: list(atom())
  30                ,num_cells       :: integer()
  31                ,num_dead        :: integer()
  32                ,num_alive       :: integer()
  33                ,state_pairs     :: list(tuple(integer(), integer())) | []
  34                ,replies_pending :: integer()
  35                ,gen_id          :: integer()
  36                }).
  37
  38
  39 %% ============================================================================
  40 %% API
  41 %% ============================================================================
  42
  43 start_link(X, Y, Cells) ->
  44     ServerName = {local, ?MODULE},
  45     Args = [X, Y, Cells],
  46     Opts = [],
  47     gen_server:start_link(ServerName, ?MODULE, Args, Opts).
  48
  49
  50 report_state(CellID, GenID, CellState) ->
  51     gen_server:cast(?MODULE, {report_state, {CellID, GenID, CellState}}).
  52
  53
  54 %% ============================================================================
  55 %% Callbacks (unused)
  56 %% ============================================================================
  57
  58 handle_call(_Msg, _From, State)  -> {reply, ok, State}.
  59 code_change(_Old, State, _Other) -> {ok, State}.
  60 terminate(_Reason, State)        -> {ok, State}.
  61
  62
  63 %% ============================================================================
  64 %% Callbacks
  65 %% ============================================================================
  66
  67 init([X, Y, Cells]) ->
  68     State = #state{x               = X
  69                   ,y               = Y
  70                   ,cells           = Cells
  71                   ,num_cells       = length(Cells)
  72                   ,state_pairs     = []
  73                   ,replies_pending = 0
  74                   ,gen_id          = 0
  75                   },
  76     ok = schedule_next_gen(),
  77     {ok, State}.
  78
  79
  80 handle_info(next_gen,
  81     #state{cells=Cells
  82           ,num_cells=NumCells
  83           ,state_pairs=[]
  84           ,gen_id=GenID
  85           }=State) ->
  86
  87     NewGenID = GenID + 1,
  88     ok = life_lib:cast_one2all(Cells, {next_gen, NewGenID}),
  89     NewState = State#state{replies_pending=NumCells
  90                           ,gen_id=NewGenID
  91                           ,num_dead=0
  92                           ,num_alive=0
  93                           },
  94     {noreply, NewState};
  95
  96 handle_info(_Msg, State) ->
  97     {noreply, State}.
  98
  99
 100 handle_cast({report_state, {CellID, GenID, CellState}},
 101     #state{x=X
 102           ,y=Y
 103           ,num_dead=NDead
 104           ,num_alive=NAlive
 105           ,state_pairs=StatePairs
 106           ,replies_pending=RepliesPending
 107           ,gen_id=GenID
 108           ,num_cells=NumCells
 109           }=State) ->
 110
 111     NewStatePairs = [{CellID, CellState} | StatePairs],
 112     NewRepliesPending = RepliesPending - 1,
 113     {NewNDead, NewNAlive} = increment_dead_or_alive(CellState, NDead, NAlive),
 114     NewState = State#state{replies_pending=NewRepliesPending
 115                           ,num_dead=NewNDead
 116                           ,num_alive=NewNAlive
 117                           },
 118
 119     case NewRepliesPending of
 120         0 ->
 121             SortedStatePairs = lists:sort(
 122                 fun({A, _}, {B, _}) -> A < B end,
 123                 NewStatePairs
 124             ),
 125             StateChars = [state_to_char(S) || {_, S} <- SortedStatePairs],
 126
 127             ok = life_observer:log_generation(GenID, NewNDead, NewNAlive),
 128
 129             ok = io:format(
 130                 "X: ~b Y: ~b CELLS: ~b DEAD: ~b ALIVE: ~b GENERATION: ~b~n",
 131                 [X, Y, NumCells, NewNDead, NewNAlive, GenID]
 132             ),
 133             ok = do_print_bar(X),
 134             ok = do_print_state_chars(X, StateChars),
 135
 136             ok = schedule_next_gen(),
 137             {noreply, NewState#state{state_pairs=[]}};
 138
 139         _N ->
 140             {noreply, NewState#state{state_pairs=NewStatePairs}}
 141     end;
 142
 143 handle_cast(_Msg, State) ->
 144     {noreply, State}.
 145
 146
 147 %% ============================================================================
 148 %% Internal
 149 %% ============================================================================
 150
 151 increment_dead_or_alive(0, NDead, NAlive) -> {NDead + 1, NAlive};
 152 increment_dead_or_alive(1, NDead, NAlive) -> {NDead, NAlive + 1}.
 153
 154
 155 schedule_next_gen() ->
 156     erlang:send_after(?INTERVAL, self(), next_gen),
 157     ok.
 158
 159
 160 state_to_char(0) -> ?CHAR_DEAD;
 161 state_to_char(1) -> ?CHAR_ALIVE.
 162
 163
 164 do_print_state_chars(_, []) -> ok;
 165 do_print_state_chars(X, Chars) ->
 166     {XChars, RestChars} = lists:split(X, Chars),
 167     ok = io:format([XChars, $\n]),
 168     do_print_state_chars(X, RestChars).
 169
 170
 171 do_print_bar(X) ->
 172     io:format("~s~n", [[?CHAR_BAR || _ <- lists:seq(1, X - 1)]]).