x2/src/awk/exe/parse_pactl_list_sinks.awk

   1 /^Sink \#[0-9]+$/ {
   2     sub("^#", "", $2)
   3     sink = $2
   4     next
   5 }
   6
   7 /\tState:/ {
   8     state[sink] = $2
   9     next
  10 }
  11
  12 /\tName:/ {
  13     name[sink] = $2
  14     next
  15 }
  16
  17 /\tMute:/ {
  18     mute[sink] = $2
  19     next
  20 }
  21
  22 # Volume: front-left: 45732 /  70% / -9.38 dB,   front-right: 45732 /  70% / -9.38 dB
  23 /\tVolume:/ {
  24     delete vol_parts
  25     delete left_parts
  26     delete right_parts
  27     sub("^\t+Volume: +", "")
  28     split($0, vol_parts, ", +")
  29     sub("^front-left: +", "", vol_parts[1])
  30     sub("^front-right: +", "", vol_parts[2])
  31     split(vol_parts[1], left_parts, " +/ +")
  32     split(vol_parts[2], right_parts, " +/ +")
  33     vol_left[sink] = left_parts[2]
  34     vol_right[sink] = right_parts[2]
  35     next
  36 }
  37
  38 END {
  39     for (sink in state) {
  40         # default_sink set via CLI
  41         if (name[sink] == default_sink) {
  42             print("state"     , state[sink])
  43             print("mute"      , mute[sink])
  44             print("vol_left"  , vol_left[sink])
  45             print("vol_right" , vol_right[sink])
  46         }
  47     }
  48 }