src/hope_option.erl

   1 -module(hope_option).
   2
   3 -behavior(hope_gen_monad).
   4
   5 -export_type(
   6     [ t/1
   7     ]).
   8
   9 -export(
  10     % Generic monad interface
  11     [ return/1
  12     , map/2
  13     , pipe/2
  14
  15     % Specific to hope_option:t()
  16     , return/2
  17     , put/2
  18     , get/2
  19     , iter/2
  20     , of_result/1
  21     , of_undefined/1
  22     , validate/2
  23     ]).
  24
  25
  26 -type t(A) ::
  27       none
  28     | {some, A}
  29     .
  30
  31
  32 -spec put(A, fun((A) -> boolean())) ->
  33     t(A).
  34 put(X, F) ->
  35     return(X, F).
  36
  37 -spec get(t(A), Default :: A) ->
  38     A.
  39 get({some, X}, _) -> X;
  40 get(none     , Y) -> Y.
  41
  42 -spec return(A) ->
  43     {some, A}.
  44 return(X) ->
  45     {some, X}.
  46
  47 -spec return(A, fun((A) -> boolean())) ->
  48     t(A).
  49 return(X, Condition) ->
  50     case Condition(X)
  51     of  true  -> {some, X}
  52     ;   false -> none
  53     end.
  54
  55 -spec map(t(A), fun((A) -> (B))) ->
  56     t(B).
  57 map({some, X}, F) -> {some, F(X)};
  58 map(none     , _) -> none.
  59
  60 -spec iter(t(A), fun((A) -> (ok))) ->
  61     ok.
  62 iter({some, X}, F) -> ok = F(X);
  63 iter(none     , _) -> ok.
  64
  65 -spec pipe([fun((A) -> t(B))], A) ->
  66     t(B).
  67 pipe([], X) ->
  68     return(X);
  69 pipe([F|Fs], X) ->
  70     case F(X)
  71     of  none      -> none
  72     ;   {some, Y} -> pipe(Fs, Y)
  73     end.
  74
  75 -spec of_result(hope_result:t(A, _B)) ->
  76     t(A).
  77 of_result({ok, X})    -> {some, X};
  78 of_result({error, _}) -> none.
  79
  80 -spec of_undefined(undefined | A) ->
  81     t(A).
  82 of_undefined(undefined) -> none;
  83 of_undefined(X)         -> {some, X}.
  84
  85 -spec validate(t(A), fun((A) -> boolean())) ->
  86     t(A).
  87 validate(none, _) ->
  88     none;
  89 validate({some, X}=T, F) ->
  90     case F(X)
  91     of  false -> none
  92     ;   true  -> T
  93     end.