+
+bar_gauge() {
+ awk "$@" '
+ BEGIN {
+ # CLI options
+ width = width ? width : 80
+ ch_left = ch_left ? ch_left : "["
+ ch_right = ch_right ? ch_right : "]"
+ ch_blank = ch_blank ? ch_blank : "-"
+ ch_used = ch_used ? ch_used : "|"
+ num = num ? 1 : 0
+ pct = pct ? 1 : 0
+ }
+
+ {
+ cur = $1
+ max = $2
+ lab = $3
+
+ cur_scaled = num_scale(cur, max, 1, width)
+
+ printf \
+ "%s%s%s%s", \
+ lab ? lab " " : "", \
+ num ? cur "/" max " " : "", \
+ pct ? sprintf("%3.0f%% ", cur / max * 100) : "", \
+ ch_left
+ for (i=1; i<=width; i++) {
+ c = i <= cur_scaled ? ch_used : ch_blank
+ printf "%s", c
+ }
+ printf "%s\n", ch_right
+ }
+
+ function num_scale(src_cur, src_max, dst_min, dst_max) {
+ return dst_min + ((src_cur * (dst_max - dst_min)) / src_max)
+ }
+ '
+}
+
+flat_top_5() {
+ sort -n -k 1 -r \
+ | head -5 \
+ | awk '
+ {
+ cur = $1
+ max = $2
+ name = $3
+ pct = cur / max * 100
+ printf "%s%s %.2f%%", sep, name, pct
+ sep = ", "
+ }
+
+ END {printf "\n"}
+ '
+}
+
+internet_addr() {
+ curl --silent --show-error --max-time "${1:=1}" 'https://api.ipify.org' 2>&1
+}
+
+status_batt() {
+ case "$(uname)" in
+ 'Linux')
+ if which upower > /dev/null
+ then
+ upower --dump \
+ | awk '
+ /^Device:[ \t]+/ {
+ device["path"] = $2
+ next
+ }
+
+ / battery/ && device["path"] {
+ device["is_battery"] = 1
+ next
+ }
+
+ / percentage:/ && device["is_battery"] {
+ device["battery_percentage"] = $2
+ sub("%$", "", device["battery_percentage"])
+ next
+ }
+
+ /^$/ {
+ if (device["is_battery"] && device["path"] == "/org/freedesktop/UPower/devices/DisplayDevice")
+ print device["battery_percentage"], 100, "batt"
+ delete device
+ }
+ '
+ fi
+ ;;
+ esac
+}
+
+indent() {
+ awk -v unit="$1" '{printf "%s%s\n", unit, $0}'
+}
+
+status() {
+ local -r indent_unit=' '
+
+ uname -srvmo
+ hostname | figlet
+ uptime
+
+ echo
+
+ echo 'accounting'
+
+ printf '%stmux\n%ssessions %d, clients %d\n' \
+ "$indent_unit" \
+ "${indent_unit}${indent_unit}" \
+ "$(tmux list-sessions 2> /dev/null | wc -l)" \
+ "$(tmux list-clients 2> /dev/null | wc -l)"
+
+ echo
+
+ printf '%sprocs by user\n' "${indent_unit}"
+ ps -eo user \
+ | awk '
+ NR > 1 {
+ count_by_user[$1]++
+ total++
+ }
+
+ END {
+ for (user in count_by_user)
+ print count_by_user[user], total, user
+ }
+ ' \
+ | flat_top_5 \
+ | indent "${indent_unit}${indent_unit}"
+
+ echo
+
+ echo 'resources'
+ (
+ free | awk '$1 == "Mem:" {print $3, $2, "mem"}'
+ df ~ | awk 'NR == 2 {print $3, $3 + $4, "disk"}'
+ status_batt
+ ) \
+ | bar_gauge -v width=60 -v pct=1 \
+ | column -t \
+ | indent "$indent_unit"
+
+ echo
+
+ printf '%smem by proc\n' "$indent_unit"
+ ps -eo rss,comm \
+ | awk -v total="$(free | awk '$1 == "Mem:" {print $2; exit}')" '
+ NR > 1 {
+ rss = $1
+ proc = $2
+ by_proc[proc] += rss
+ }
+
+ END {
+ for (proc in by_proc)
+ print by_proc[proc], total, proc
+ }
+ ' \
+ | flat_top_5 \
+ | indent "${indent_unit}${indent_unit}"
+
+ echo
+
+ local _dir temp_input label_file label
+
+ printf '%sthermal\n' "$indent_unit"
+ for _dir in /sys/class/hwmon/hwmon*; do
+ cat "$_dir"/name
+ find "$_dir"/ -name 'temp*_input' \
+ | while read -r temp_input; do
+ label_file=${temp_input//_input/_label}
+ if [ -f "$label_file" ]; then
+ label=$(< "$label_file")
+ else
+ label=''
+ fi
+ awk -v label="$label" '{
+ if (label)
+ label = sprintf(" (%s)", label)
+ printf("%.2f°C%s\n", $1 / 1000, label)
+ }' \
+ "$temp_input"
+ done \
+ | sort \
+ | indent "$indent_unit"
+ done \
+ | indent "${indent_unit}${indent_unit}"
+
+ echo 'net'
+ #local -r internet_addr=$(internet_addr 0.5)
+ #local -r internet_ptr=$(host -W 1 "$internet_addr" | awk 'NR == 1 {print $NF}' )
+
+ #echo "${indent_unit}internet"
+ #echo "${indent_unit}${indent_unit}$internet_addr $internet_ptr"
+ echo "${indent_unit}if"
+ (ifconfig; iwconfig) 2> /dev/null \
+ | awk '
+ /^[^ ]/ {
+ device = $1
+ sub(":$", "", device)
+ if ($4 ~ "ESSID:") {
+ _essid = $4
+ sub("^ESSID:\"", "", _essid)
+ sub("\"$", "", _essid)
+ essid[device] = _essid
+ }
+ next
+ }
+
+ /^ / && $1 == "inet" {
+ address[device] = $2
+ next
+ }
+
+ /^ +Link Quality=[0-9]+\/[0-9]+ +Signal level=/ {
+ split($2, lq_parts_eq, "=")
+ split(lq_parts_eq[2], lq_parts_slash, "/")
+ cur = lq_parts_slash[1]
+ max = lq_parts_slash[2]
+ link[device] = cur / max * 100
+ next
+ }
+
+ END {
+ for (device in address)
+ if (device != "lo") {
+ l = link[device]
+ e = essid[device]
+ l = l ? sprintf("%.0f%%", l) : "--"
+ e = e ? e : "--"
+ print device, address[device], e, l
+ }
+ }
+ ' \
+ | column -t \
+ | indent "${indent_unit}${indent_unit}"
+
+ # WARN: ensure: $USER ALL=(ALL) NOPASSWD:/bin/netstat
+
+ echo "${indent_unit}-->"
+
+ sudo -n netstat -tulnp \
+ | awk -v indent="${indent_unit}${indent_unit}" '
+ NR > 2 && ((/^tcp/ && proc = $7) || (/^udp/ && proc = $6)) {
+ protocol = $1
+ addr = $4
+ port = a[split(addr, a, ":")]
+ name = p[split(proc, p, "/")]
+ names[name] = 1
+ protocols[protocol] = 1
+ if (!seen[protocol, name, port]++)
+ ports[protocol, name, ++seen[protocol, name]] = port
+ }
+
+ END {
+ for (protocol in protocols) {
+ printf "%s%s\t", indent, toupper(protocol)
+ for (name in names) {
+ if (n = seen[protocol, name]) {
+ sep = ""
+ printf "%s:", name
+ for (i = 1; i <= n; i++) {
+ printf "%s%d", sep, ports[protocol, name, i]
+ sep = ","
+ }
+ printf " "
+ }
+ }
+ printf "\n"
+ }
+ }'
+
+ echo "${indent_unit}<->"
+
+ printf '%sTCP\t' "${indent_unit}${indent_unit}"
+ sudo -n netstat -tnp \
+ | awk 'NR > 2 && $6 == "ESTABLISHED" {print $7}' \
+ | awk '{sub("^[0-9]+/", ""); print}' \
+ | sort -u \
+ | xargs \
+ | column -t
+
+ # TODO: iptables summary
+}
+
+ssh_invalid_by_addr() {
+ awk '
+ /: Invalid user/ && $5 ~ /^sshd/ {
+ addr=$10 == "port" ? $9 : $10
+ max++
+ by_addr[addr]++
+ }
+
+ END {
+ for (addr in by_addr)
+ if ((c = by_addr[addr]) > 1)
+ printf "%d %d %s\n", c, max, addr
+ }
+ ' \
+ /var/log/auth.log \
+ /var/log/auth.log.1 \
+ | sort -n -k 1 \
+ | bar_gauge -v width="$(stty size | awk '{print $2}')" -v num=1 -v ch_right=' ' -v ch_left=' ' -v ch_blank=' ' \
+ | column -t
+}
+
+ssh_invalid_by_day() {
+ awk '
+ BEGIN {
+ m["Jan"] = "01"
+ m["Feb"] = "02"
+ m["Mar"] = "03"
+ m["Apr"] = "04"
+ m["May"] = "05"
+ m["Jun"] = "06"
+ m["Jul"] = "07"
+ m["Aug"] = "08"
+ m["Sep"] = "09"
+ m["Oct"] = "10"
+ m["Nov"] = "11"
+ m["Dec"] = "12"
+ }
+
+ /: Invalid user/ && $5 ~ /^sshd/ {
+ day = m[$1] "-" $2
+ max++
+ by_day[day]++
+ }
+
+ END {
+ for (day in by_day)
+ if ((c = by_day[day]) > 1)
+ printf "%d %d %s\n", c, max, day
+ }
+ ' \
+ /var/log/auth.log \
+ /var/log/auth.log.1 \
+ | sort -k 3 \
+ | bar_gauge -v width="$(stty size | awk '{print $2}')" -v num=1 -v ch_right=' ' -v ch_left=' ' -v ch_blank=' ' \
+ | column -t
+}
+
+ssh_invalid_by_user() {
+ awk '
+ /: Invalid user/ && $5 ~ /^sshd/ {
+ user=$8
+ max++
+ by_user[user]++
+ }
+
+ END {
+ for (user in by_user)
+ if ((c = by_user[user]) > 1)
+ printf "%d %d %s\n", c, max, user
+ }
+ ' \
+ /var/log/auth.log \
+ /var/log/auth.log.1 \
+ | sort -n -k 1 \
+ | bar_gauge -v width="$(stty size | awk '{print $2}')" -v num=1 -v ch_right=' ' -v ch_left=' ' -v ch_blank=' ' \
+ | column -t
+}
+
+loggers() {
+ awk '
+ {
+ split($5, prog, "[")
+ sub(":$", "", prog[1]) # if there were no [], than : will is left behind
+ print prog[1]
+ }' /var/log/syslog /var/log/syslog.1 \
+ | awk '
+ {
+ n = split($1, path, "/") # prog may be in path form
+ prog = path[n]
+ total++
+ count[prog]++
+ }
+
+ END {
+ for (prog in count)
+ print count[prog], total, prog
+ }' \
+ | sort -n -k 1 \
+ | bar_gauge -v num=1 -v ch_right=' ' -v ch_left=' ' -v ch_blank=' ' \
+ | column -t
+}