Commit | Line | Data |
---|---|---|
75b23ff8 SK |
1 | #! /usr/bin/awk -f |
2 | ||
c4fd5e7d SK |
3 | # Naming convention: |
4 | # Variables: | |
5 | # - global, builtin : ALLCAPS | |
b1c097d6 | 6 | # - global, public : Camel_Snake_Man_Bear_Pig |
c4fd5e7d SK |
7 | # - global, private : _snake_case_prefixed_underscore |
8 | # - local : snake_case | |
9 | # Functions: | |
10 | # - global, public : snake_case | |
11 | ||
75b23ff8 SK |
12 | BEGIN { |
13 | FS = msg_fs ? msg_fs : "|" | |
14 | OFS = msg_fs ? msg_fs : "|" | |
15 | Kfs = key_fs ? key_fs : ":" | |
2d710f28 | 16 | GC_Interval = GC_Interval ? GC_Interval : 3600 # seconds |
bd3e26c8 SK |
17 | |
18 | _total_to_diff["khatus_sensor_net_addr_io", "bytes_read" ] = 1 | |
19 | _total_to_diff["khatus_sensor_net_addr_io", "bytes_written" ] = 1 | |
20 | _total_to_diff["khatus_sensor_disk_io" , "sectors_read" ] = 1 | |
21 | _total_to_diff["khatus_sensor_disk_io" , "sectors_written"] = 1 | |
2d07b264 SK |
22 | |
23 | # (x * y) / z = x * w | |
24 | # ==> w = y / z | |
25 | # (x * bytes_per_sector) / bytes_per_mb = x * scaling_factor | |
26 | # ==> scaling_factor = bytes_per_sector / bytes_per_mb | |
c4fd5e7d SK |
27 | _bytes_per_sector = 512 |
28 | _bytes_per_mb = 1024 * 1024 | |
29 | _scale["khatus_sensor_disk_io", "sectors_written"] = _bytes_per_sector / _bytes_per_mb | |
30 | _scale["khatus_sensor_disk_io", "sectors_read" ] = _bytes_per_sector / _bytes_per_mb | |
2d07b264 SK |
31 | # (x / y) = x * z |
32 | # ==> z = 1 / y | |
33 | # x / bytes_per_mb = x * scaling_factor | |
34 | # ==> scaling_factor = 1 / bytes_per_mb | |
c4fd5e7d SK |
35 | _scale["khatus_sensor_net_addr_io", "bytes_written"] = 1 / _bytes_per_mb |
36 | _scale["khatus_sensor_net_addr_io", "bytes_read" ] = 1 / _bytes_per_mb | |
75b23ff8 SK |
37 | } |
38 | ||
39 | # ----------------------------------------------------------------------------- | |
40 | # Input | |
41 | # ----------------------------------------------------------------------------- | |
42 | $1 == "OK" { | |
c4fd5e7d | 43 | cache_update() |
75b23ff8 SK |
44 | } |
45 | ||
46 | $1 == "OK" && \ | |
47 | $2 == "khatus_sensor_datetime" { | |
48 | print_msg_ok("status_bar", make_status_bar()) | |
49 | } | |
50 | ||
75b23ff8 | 51 | # ----------------------------------------------------------------------------- |
c4fd5e7d | 52 | # Cache |
75b23ff8 SK |
53 | # ----------------------------------------------------------------------------- |
54 | ||
c4fd5e7d | 55 | function cache_update( src, key, val, len_line, len_head, len_val, time) { |
75b23ff8 SK |
56 | src = $2 |
57 | key = $3 | |
75b23ff8 SK |
58 | # Not just using $4 for val - because an unstructured value (like name of a |
59 | # song) might contain a character identical to FS | |
60 | len_line = length($0) | |
61 | len_head = length($1 FS $2 FS $3 FS) | |
62 | len_val = len_line - len_head | |
63 | val = substr($0, len_head + 1, len_val) | |
c4fd5e7d SK |
64 | val = cache_maybe_total_to_diff(src, key, val) |
65 | val = cache_maybe_scale(src, key, val) | |
66 | _cache[src, key] = val | |
67 | time = cache_get_time() | |
68 | _cache_mtime[src, key] = time | |
2d710f28 | 69 | if (time % GC_Interval == 0) { |
c4fd5e7d | 70 | cache_gc() |
75b23ff8 SK |
71 | } |
72 | } | |
73 | ||
c4fd5e7d SK |
74 | function cache_get(result, src, key, ttl, time, age, is_expired) { |
75 | time = cache_get_time() | |
76 | _cache_atime[src, key] = time | |
77 | age = time - _cache_mtime[src, key] | |
78 | result["is_expired"] = ttl && age > ttl # ttl = 0 => forever | |
79 | result["value"] = _cache[src, key] | |
269df6fa SK |
80 | } |
81 | ||
c4fd5e7d | 82 | function cache_res_fmt_or_def(result, format, default) { |
269df6fa SK |
83 | return result["is_expired"] ? default : sprintf(format, result["value"]) |
84 | } | |
85 | ||
c4fd5e7d | 86 | function cache_get_fmt_def(src, key, ttl, format, default, result) { |
269df6fa | 87 | default = default ? default : "--" |
c4fd5e7d SK |
88 | cache_get(result, src, key, ttl) |
89 | return cache_res_fmt_or_def(result, format, default) | |
75b23ff8 SK |
90 | } |
91 | ||
c4fd5e7d | 92 | function cache_get_time( src, key, time) { |
75b23ff8 SK |
93 | src = "khatus_sensor_datetime" |
94 | key = "epoch" | |
c4fd5e7d SK |
95 | time = _cache[src, key] |
96 | _cache_atime[src, key] = time | |
75b23ff8 SK |
97 | return time |
98 | } | |
99 | ||
9151826a | 100 | function cache_gc( src_and_key, parts, src, key, unused_for) { |
c4fd5e7d | 101 | for (src_and_key in _cache) { |
9151826a SK |
102 | split(src_and_key, parts, SUBSEP) |
103 | src = parts[1] | |
104 | key = parts[2] | |
b9d5cfd4 | 105 | val = _cache[src, key] |
9151826a | 106 | unused_for = cache_get_time() - _cache_atime[src, key] |
2d710f28 | 107 | if (unused_for > GC_Interval) { |
171acde3 | 108 | print_msg_info(\ |
9151826a | 109 | "cache_gc", |
b9d5cfd4 SK |
110 | sprintf(\ |
111 | "Deleting unused data SRC=%s KEY=%s VAL=%s", | |
112 | src, key, val\ | |
113 | ) \ | |
75b23ff8 | 114 | ) |
9151826a | 115 | delete _cache[src, key] |
75b23ff8 SK |
116 | } |
117 | } | |
118 | } | |
119 | ||
c4fd5e7d | 120 | function cache_maybe_total_to_diff(src, key, val, key_parts) { |
bd3e26c8 SK |
121 | split(key, key_parts, Kfs) |
122 | if (_total_to_diff[src, key_parts[1]]) { | |
123 | _prev[src, key] = _curr[src, key] | |
124 | _curr[src, key] = val | |
125 | return (_curr[src, key] - _prev[src, key]) | |
126 | } else { | |
127 | return val | |
128 | } | |
129 | } | |
130 | ||
c4fd5e7d | 131 | function cache_maybe_scale(src, key, val, key_parts) { |
2d07b264 SK |
132 | split(key, key_parts, Kfs) |
133 | if ((src SUBSEP key_parts[1]) in _scale) { | |
134 | return val * _scale[src, key_parts[1]] | |
135 | } else { | |
136 | return val | |
137 | } | |
138 | } | |
139 | ||
75b23ff8 SK |
140 | # ----------------------------------------------------------------------------- |
141 | # Status bar | |
142 | # ----------------------------------------------------------------------------- | |
143 | ||
144 | function make_status_bar( position, bar, sep, i, j) { | |
145 | position[++i] = "" | |
146 | position[++i] = make_status_energy() | |
147 | position[++i] = make_status_mem() | |
b9d5cfd4 | 148 | position[++i] = make_status_procs() |
75b23ff8 SK |
149 | position[++i] = make_status_cpu() |
150 | position[++i] = make_status_disk() | |
151 | position[++i] = make_status_net() | |
152 | position[++i] = make_status_bluetooth() | |
153 | position[++i] = make_status_screen_brightness() | |
154 | position[++i] = make_status_volume() | |
155 | position[++i] = make_status_mpd() | |
156 | position[++i] = make_status_weather() | |
157 | position[++i] = make_status_datetime() | |
158 | position[++i] = "" | |
159 | bar = "" | |
160 | sep = "" | |
161 | for (j = 1; j <= i; j++) { | |
162 | bar = bar sep position[j] | |
163 | sep = " " | |
164 | } | |
165 | return bar | |
166 | } | |
167 | ||
168 | function make_status_energy( state, charge, direction_of_change) { | |
c4fd5e7d SK |
169 | cache_get(state , "khatus_sensor_energy", "battery_state" , 0) |
170 | cache_get(charge, "khatus_sensor_energy", "battery_percentage", 0) | |
75b23ff8 | 171 | |
269df6fa | 172 | if (state["value"] == "discharging") { |
75b23ff8 | 173 | direction_of_change = "<" |
269df6fa | 174 | } else if (state["value"] == "charging") { |
75b23ff8 SK |
175 | direction_of_change = ">" |
176 | } else { | |
177 | direction_of_change = "=" | |
178 | } | |
179 | ||
269df6fa | 180 | return sprintf("E%s%d%%", direction_of_change, charge["value"]) |
75b23ff8 SK |
181 | } |
182 | ||
183 | function make_status_mem( total, used, percent, status) { | |
c4fd5e7d SK |
184 | cache_get(total, "khatus_sensor_memory", "total", 5) |
185 | cache_get(used , "khatus_sensor_memory", "used" , 5) | |
269df6fa SK |
186 | # Checking total["value"] to avoid division by zero when data is missing |
187 | if (!total["is_expired"] && \ | |
188 | !used["is_expired"] && \ | |
189 | total["value"] \ | |
190 | ) { | |
191 | percent = round((used["value"] / total["value"]) * 100) | |
75b23ff8 SK |
192 | status = sprintf("%d%%", percent) |
193 | } else { | |
194 | status = "__" | |
195 | } | |
196 | return sprintf("M=%s", status) | |
197 | } | |
198 | ||
b9d5cfd4 SK |
199 | function make_status_procs() { |
200 | src = "khatus_sensor_procs" | |
201 | all = cache_get_fmt_def(src, "total_procs" , 15, "%d") | |
202 | r = cache_get_fmt_def(src, "total_per_state" Kfs "R", 15, "%d", "0") | |
203 | d = cache_get_fmt_def(src, "total_per_state" Kfs "D", 15, "%d", "0") | |
204 | t = cache_get_fmt_def(src, "total_per_state" Kfs "T", 15, "%d", "0") | |
205 | i = cache_get_fmt_def(src, "total_per_state" Kfs "I", 15, "%d", "0") | |
206 | z = cache_get_fmt_def(src, "total_per_state" Kfs "Z", 15, "%d", "0") | |
207 | return sprintf("P=[%s %sr %sd %st %si %sz]", all, r, d, t, i, z) | |
208 | } | |
209 | ||
269df6fa | 210 | function make_status_cpu( l, t, f) { |
fd710ac0 SK |
211 | l_src = "khatus_sensor_loadavg" |
212 | t_src = "khatus_sensor_temperature" | |
213 | f_src = "khatus_sensor_fan" | |
214 | l = cache_get_fmt_def(l_src, "load_avg_1min", 5, "%4.2f") | |
215 | t = cache_get_fmt_def(t_src, "temp_c" , 5, "%d" ) | |
216 | f = cache_get_fmt_def(f_src, "speed" , 5, "%4d" ) | |
269df6fa | 217 | return sprintf("C=[%s %s°C %srpm]", l, t, f) |
75b23ff8 SK |
218 | } |
219 | ||
fd710ac0 SK |
220 | function make_status_disk( u, w, r, src_u, src_io) { |
221 | src_u = "khatus_sensor_disk_space" | |
222 | src_io = "khatus_sensor_disk_io" | |
224be98a SK |
223 | u = cache_get_fmt_def(src_u , "disk_usage_percentage", 10, "%s") |
224 | w = cache_get_fmt_def(src_io, "sectors_written" , 5, "%0.3f") | |
225 | r = cache_get_fmt_def(src_io, "sectors_read" , 5, "%0.3f") | |
2d07b264 | 226 | return sprintf("D=[%s%% %s▲ %s▼]", u, w, r) |
75b23ff8 SK |
227 | } |
228 | ||
229 | function make_status_net( \ | |
230 | number_of_net_interfaces_to_show, \ | |
231 | net_interfaces_to_show, \ | |
fd710ac0 SK |
232 | io, \ |
233 | wi, \ | |
75b23ff8 SK |
234 | i, \ |
235 | interface, \ | |
236 | label, \ | |
2d07b264 | 237 | wifi, \ |
75b23ff8 SK |
238 | addr, \ |
239 | w, \ | |
240 | r, \ | |
75b23ff8 | 241 | io_stat, \ |
2d07b264 SK |
242 | out, \ |
243 | sep \ | |
75b23ff8 SK |
244 | ) { |
245 | number_of_net_interfaces_to_show = \ | |
b1c097d6 | 246 | split(Opt_Net_Interfaces_To_Show, net_interfaces_to_show, ",") |
fd710ac0 SK |
247 | io = "khatus_sensor_net_addr_io" |
248 | wi = "khatus_sensor_net_wifi_status" | |
75b23ff8 SK |
249 | out = "" |
250 | sep = "" | |
251 | for (i = number_of_net_interfaces_to_show; i > 0; i--) { | |
252 | interface = net_interfaces_to_show[i] | |
253 | label = substr(interface, 1, 1) | |
75b23ff8 | 254 | if (interface ~ "^w") { |
fd710ac0 | 255 | wifi = cache_get_fmt_def(wi, "status" Kfs interface, 10, "%s") |
269df6fa | 256 | label = label ":" wifi |
75b23ff8 | 257 | } |
fd710ac0 SK |
258 | addr = cache_get_fmt_def(io, "addr" Kfs interface, 5, "%s", "") |
259 | w = cache_get_fmt_def(io, "bytes_written" Kfs interface, 5, "%0.3f") | |
260 | r = cache_get_fmt_def(io, "bytes_read" Kfs interface, 5, "%0.3f") | |
2d07b264 | 261 | io_stat = addr ? sprintf("%s▲ %s▼", w, r) : "--" |
75b23ff8 SK |
262 | out = out sep label ":" io_stat |
263 | sep = " " | |
264 | } | |
75b23ff8 SK |
265 | return sprintf("N[%s]", out) |
266 | } | |
267 | ||
269df6fa SK |
268 | function make_status_bluetooth( src, key) { |
269 | src = "khatus_sensor_bluetooth_power" | |
270 | key = "power_status" | |
c4fd5e7d | 271 | return sprintf("B=%s", cache_get_fmt_def(src, key, 10, "%s")) |
75b23ff8 SK |
272 | } |
273 | ||
269df6fa SK |
274 | function make_status_screen_brightness( src, key) { |
275 | src = "khatus_sensor_screen_brightness" | |
276 | key = "percentage" | |
c4fd5e7d | 277 | return sprintf("*%s%%", cache_get_fmt_def(src, key, 5, "%d")) |
75b23ff8 SK |
278 | } |
279 | ||
fd710ac0 | 280 | function make_status_volume( sink, mu, vl, vr, show) { |
b1c097d6 | 281 | sink = Opt_Pulseaudio_Sink |
fd710ac0 SK |
282 | cache_get(mu, "khatus_sensor_volume", "mute" Kfs sink, 5) |
283 | cache_get(vl, "khatus_sensor_volume", "vol_left" Kfs sink, 5) | |
284 | cache_get(vr, "khatus_sensor_volume", "vol_right" Kfs sink, 5) | |
767766df | 285 | show = "--" |
fd710ac0 SK |
286 | if (!mu["is_expired"] && !vl["is_expired"] && !vr["is_expired"]) { |
287 | if (mu["value"] == "yes") {show = "X"} | |
288 | else if (mu["value"] == "no") {show = vl["value"] " " vr["value"]} | |
75b23ff8 SK |
289 | else { |
290 | print_msg_error(\ | |
291 | "make_status_volume", \ | |
fd710ac0 | 292 | "Unexpected value for 'mute' field: " mu["value"] \ |
75b23ff8 SK |
293 | ) |
294 | } | |
75b23ff8 | 295 | } |
269df6fa | 296 | return sprintf("(%s)", show) |
75b23ff8 SK |
297 | } |
298 | ||
299 | function make_status_mpd( state, status) { | |
c4fd5e7d | 300 | cache_get(state, "khatus_sensor_mpd", "state", 5) |
269df6fa SK |
301 | if (!state["is_expired"] && state["value"]) { |
302 | if (state["value"] == "play") { | |
75b23ff8 | 303 | status = make_status_mpd_state_known("▶") |
269df6fa | 304 | } else if (state["value"] == "pause") { |
75b23ff8 | 305 | status = make_status_mpd_state_known("❚❚") |
269df6fa | 306 | } else if (state["value"] == "stop") { |
75b23ff8 SK |
307 | status = make_status_mpd_state_known("⬛") |
308 | } else { | |
309 | print_msg_error(\ | |
310 | "make_status_mpd", \ | |
269df6fa | 311 | "Unexpected value for 'state' field: " state["value"] \ |
75b23ff8 SK |
312 | ) |
313 | status = "--" | |
314 | } | |
315 | } else { | |
316 | status = "--" | |
317 | } | |
318 | ||
319 | return sprintf("[%s]", status) | |
320 | } | |
321 | ||
322 | function make_status_mpd_state_known(symbol, s, song, time, percentage) { | |
323 | s = "khatus_sensor_mpd" | |
c4fd5e7d SK |
324 | song = cache_get_fmt_def(s, "song" , 5, "%s", "?") |
325 | time = cache_get_fmt_def(s, "play_time_minimal_units", 5, "%s", "?") | |
326 | percent = cache_get_fmt_def(s, "play_time_percentage" , 5, "%s", "?") | |
b1c097d6 | 327 | song = substr(song, 1, Opt_Mpd_Song_Max_Chars) |
75b23ff8 SK |
328 | return sprintf("%s %s %s %s", symbol, time, percent, song) |
329 | } | |
330 | ||
fd710ac0 SK |
331 | function make_status_weather( src, hour, t_f) { |
332 | src = "khatus_sensor_weather" | |
75b23ff8 | 333 | hour = 60 * 60 |
fd710ac0 | 334 | t_f = cache_get_fmt_def(src, "temperature_f", 3 * hour, "%d") |
75b23ff8 SK |
335 | return sprintf("%s°F", t_f) |
336 | } | |
337 | ||
338 | function make_status_datetime( dt) { | |
c4fd5e7d | 339 | return cache_get_fmt_def("khatus_sensor_datetime", "datetime", 5, "%s") |
75b23ff8 SK |
340 | } |
341 | ||
342 | # ----------------------------------------------------------------------------- | |
343 | # Output | |
344 | # ----------------------------------------------------------------------------- | |
345 | ||
346 | function print_msg_ok(key, val) { | |
347 | print_msg("OK", key, val, "/dev/stdout") | |
348 | } | |
349 | ||
171acde3 SK |
350 | function print_msg_info(location, msg) { |
351 | print_msg("INFO", location, msg, "/dev/stderr") | |
352 | } | |
353 | ||
75b23ff8 SK |
354 | function print_msg_error(location, msg) { |
355 | print_msg("ERROR", location, msg, "/dev/stderr") | |
356 | } | |
357 | ||
358 | function print_msg(status, key, val, channel) { | |
359 | print(status, "khatus_bar", key, val) > channel | |
360 | } | |
361 | ||
362 | # ----------------------------------------------------------------------------- | |
363 | # Numbers | |
364 | # ----------------------------------------------------------------------------- | |
365 | ||
366 | function round(n) { | |
367 | return int(n + 0.5) | |
368 | } |