tt.rkt

   1 #lang typed/racket/no-check
   2
   3 (require openssl/sha1)
   4 (require racket/date)
   5 (require
   6   net/head
   7   net/uri-codec
   8   net/url)
   9
  10 (require (prefix-in info: "info.rkt"))
  11
  12 (module+ test
  13   (require rackunit))
  14
  15 (define-type Url
  16   net/url-structs:url)
  17
  18 (define-type Out-Format
  19   (U 'single-line
  20      'multi-line))
  21
  22 (define-type Timeline-Order
  23   (U 'old->new
  24      'new->old))
  25
  26 (struct Msg
  27         ([ts-epoch   : Integer]
  28          [ts-orig    : String]
  29          [nick       : (Option String)]
  30          [uri        : Url]
  31          [text       : String]
  32          [mentions   : (Listof Peer)]))
  33
  34 (struct Peer
  35         ([nick : (Option String)]
  36          [uri  : Url])
  37         #:transparent)
  38
  39 (struct Resp
  40         ([status-line : String]
  41          [headers     : (Listof Bytes)]
  42          [body-input  : Input-Port]))
  43
  44 (: tt-home-dir Path-String)
  45 (define tt-home-dir (build-path (expand-user-path "~") ".tt"))
  46
  47 (: concurrent-filter-map (∀ (α β) (-> Natural (-> α β) (Listof α) (Listof β))))
  48 (define (concurrent-filter-map num-workers f xs)
  49   ; TODO preserve order of elements OR communicate that reorder is expected
  50   ; TODO switch from mailboxes to channels
  51   (define (make-worker id f)
  52     (define parent (current-thread))
  53     (λ ()
  54        (define self : Thread (current-thread))
  55        (: work (∀ (α) (-> α)))
  56        (define (work)
  57          (thread-send parent (cons 'next self))
  58          (match (thread-receive)
  59            ['done          (thread-send parent (cons 'exit id))]
  60            [(cons 'unit x) (begin
  61                              (define y (f x))
  62                              (when y (thread-send parent (cons 'result y)))
  63                              (work))]))
  64        (work)))
  65   (: dispatch (∀ (α β) (-> (Listof Nonnegative-Integer) (Listof α) (Listof β))))
  66   (define (dispatch ws xs ys)
  67     (if (empty? ws)
  68         ys
  69         (match (thread-receive)
  70           [(cons 'exit w)   (dispatch (remove w ws =) xs ys)]
  71           [(cons 'result y) (dispatch ws xs (cons y ys))]
  72           [(cons 'next thd) (match xs
  73                               ['()         (begin
  74                                              (thread-send thd 'done)
  75                                              (dispatch ws xs ys))]
  76                               [(cons x xs) (begin
  77                                              (thread-send thd (cons 'unit x))
  78                                              (dispatch ws xs ys))])])))
  79   (define workers (range num-workers))
  80   (define threads (map (λ (id) (thread (make-worker id f))) workers))
  81   (define results (dispatch workers xs '()))
  82   (for-each thread-wait threads)
  83   results)
  84
  85 (module+ test
  86   (let* ([f        (λ (x) (if (even? x) x #f))]
  87          [xs       (range 11)]
  88          [actual   (sort (concurrent-filter-map 10 f xs) <)]
  89          [expected (sort (           filter-map    f xs) <)])
  90     (check-equal? actual expected "concurrent-filter-map")))
  91
  92 (: msg-print (-> Out-Format Integer Msg Void))
  93 (define msg-print
  94   (let* ([colors (vector 36 33)]
  95          [n      (vector-length colors)])
  96     (λ (out-format color-i msg)
  97        (let ([color (vector-ref colors (modulo color-i n))]
  98              [nick  (Msg-nick msg)]
  99              [uri   (url->string (Msg-uri msg))]
 100              [text  (Msg-text msg)]
 101              [mentions (Msg-mentions msg)])
 102          (match out-format
 103            ['single-line
 104             (let ([nick (if nick nick uri)])
 105               (printf "~a  \033[1;37m<~a>\033[0m  \033[0;~am~a\033[0m~n"
 106                       (parameterize
 107                         ([date-display-format 'iso-8601])
 108                         (date->string (seconds->date (Msg-ts-epoch msg)) #t))
 109                       nick color text))]
 110            ['multi-line
 111             (let ([nick (if nick (string-append nick " ") "")])
 112               (printf "~a (~a)~n\033[1;37m<~a~a>\033[0m~n\033[0;~am~a\033[0m~n~n"
 113                       (parameterize
 114                         ([date-display-format 'rfc2822])
 115                         (date->string (seconds->date (Msg-ts-epoch msg)) #t))
 116                       (Msg-ts-orig msg)
 117                       nick uri color text))])))))
 118
 119 (: rfc3339->epoch (-> String (Option Nonnegative-Integer)))
 120 (define rfc3339->epoch
 121   (let ([re (pregexp "^([0-9]{4})-([0-9]{2})-([0-9]{2})T([0-9]{2}):([0-9]{2})(:([0-9]{2}))?(\\.[0-9]+)?(Z|([+-])([0-9]{1,2}):?([0-9]{2}))?$")])
 122     (λ (ts)
 123        (match (regexp-match re ts)
 124          [(list _wholething yyyy mm dd HH MM _:SS SS _fractional tz-whole tz-sign tz-HH tz-MM)
 125           (let*
 126             ([tz-offset
 127                (match* (tz-whole tz-sign tz-HH tz-MM)
 128                  [("Z" #f #f #f)
 129                   0]
 130                  [(_  (or "-" "+") (? identity h)  (? identity m))
 131                   (let ([h (string->number h)]
 132                         [m (string->number m)]
 133                         ; Reverse to get back to UTC:
 134                         [op (match tz-sign ["+" -] ["-" +])])
 135                     (op 0 (+ (* 60 m) (* 60 (* 60 h)))))]
 136                  [(a b c d)
 137                   (log-warning "Impossible TZ string: ~v, components: ~v ~v ~v ~v" tz-whole a b c d)
 138                   0])]
 139              [ts-orig ts]
 140              [local-time? #f]
 141              [ts-epoch (find-seconds (if SS (string->number SS) 0)
 142                                      (string->number MM)
 143                                      (string->number HH)
 144                                      (string->number dd)
 145                                      (string->number mm)
 146                                      (string->number yyyy)
 147                                      local-time?)])
 148             (+ ts-epoch tz-offset))]
 149          [_
 150            (log-error "Invalid timestamp: ~v" ts)
 151            #f]))))
 152
 153 (: str->msg (-> (Option String) Url String (Option Msg)))
 154 (define str->msg
 155   (let ([re (pregexp "^([^\\s\t]+)[\\s\t]+(.*)$")])
 156     (λ (nick uri str)
 157        (define str-head (substring str 0 (min 100 (string-length str))))
 158        (with-handlers*
 159          ([exn:fail?
 160             (λ (e)
 161                (log-error
 162                  "Failed to parse msg: ~v, from: ~v, at: ~v, because: ~v"
 163                  str-head nick (url->string uri) e)
 164                #f)])
 165          (match (regexp-match re str)
 166            [(list _wholething ts-orig text)
 167             (let ([ts-epoch (rfc3339->epoch ts-orig)])
 168               (if ts-epoch
 169                   (let ([mentions
 170                           (filter-map
 171                             (λ (m) (match (regexp-match #px"@<([^>]+)>" m)
 172                                      [(list _wholething nick-uri)
 173                                       (str->peer nick-uri)]))
 174                             (regexp-match* #px"@<[^\\s]+([\\s]+)?[^>]+>" text))])
 175                     (Msg ts-epoch ts-orig nick uri text mentions))
 176                   (begin
 177                     (log-error
 178                       "Msg rejected due to invalid timestamp: ~v, nick:~v, uri:~v"
 179                       str-head nick (url->string uri))
 180                     #f)))]
 181            [_
 182              (log-debug "Non-msg line from nick:~v, line:~a" nick str-head)
 183              #f])))))
 184
 185 (module+ test
 186   ; TODO Test for when missing-nick case
 187   (let* ([tzs (for*/list ([d '("-" "+")]
 188                           [h '("5" "05")]
 189                           [m '("00" ":00" "57" ":57")])
 190                          (string-append d h m))]
 191          [tzs (list* "" "Z" tzs)])
 192     (for* ([n   '("fake-nick")]
 193            [u   '("fake-uri")]
 194            [s   '("" ":10")]
 195            [f   '("" ".1337")]
 196            [z   tzs]
 197            [sep (list "\t" " ")]
 198            [txt '("foo bar baz" "'jaz poop bear giraffe / tea" "@*\"``")])
 199           (let* ([ts (string-append "2020-11-18T22:22"
 200                                     (if (non-empty-string? s) s ":00")
 201                                     z)]
 202                  [m  (str->msg n u (string-append ts sep txt))])
 203             (check-not-false m)
 204             (check-equal? (Msg-nick m) n)
 205             (check-equal? (Msg-uri m) u)
 206             (check-equal? (Msg-text m) txt)
 207             (check-equal? (Msg-ts-orig m) ts (format "Given: ~v" ts))
 208             )))
 209
 210   (let* ([ts       "2020-11-18T22:22:09-0500"]
 211          [tab      "    "]
 212          [text     "Lorem ipsum"]
 213          [nick     "foo"]
 214          [uri      "bar"]
 215          [actual   (str->msg nick uri (string-append ts tab text))]
 216          [expected (Msg 1605756129 ts nick uri text '())])
 217     (check-equal?
 218       (Msg-ts-epoch actual)
 219       (Msg-ts-epoch expected)
 220       "str->msg ts-epoch")
 221     (check-equal?
 222       (Msg-ts-orig actual)
 223       (Msg-ts-orig expected)
 224       "str->msg ts-orig")
 225     (check-equal?
 226       (Msg-nick actual)
 227       (Msg-nick expected)
 228       "str->msg nick")
 229     (check-equal?
 230       (Msg-uri actual)
 231       (Msg-uri expected)
 232       "str->msg uri")
 233     (check-equal?
 234       (Msg-text actual)
 235       (Msg-text expected)
 236       "str->msg text")))
 237
 238 (: str->lines (-> String (Listof String)))
 239 (define (str->lines str)
 240   (string-split str (regexp "[\r\n]+")))
 241
 242 (module+ test
 243   (check-equal? (str->lines "abc\ndef\n\nghi") '("abc" "def" "ghi")))
 244
 245 (: str->msgs (-> (Option String) Url String (Listof Msg)))
 246 (define (str->msgs nick uri str)
 247   (filter-map (λ (line) (str->msg nick uri line)) (filter-comments (str->lines str))))
 248
 249 (: cache-dir Path-String)
 250 (define cache-dir (build-path tt-home-dir "cache"))
 251
 252 (define cache-object-dir (build-path cache-dir "objects"))
 253
 254 (: url->cache-file-path-v1 (-> Url Path-String))
 255 (define (url->cache-file-path-v1 uri)
 256   (define (hash-sha1 str) : (-> String String)
 257     (define in (open-input-string str))
 258     (define digest (sha1 in))
 259     (close-input-port in)
 260     digest)
 261   (build-path cache-object-dir (hash-sha1 (url->string uri))))
 262
 263 (: url->cache-file-path-v2 (-> Url Path-String))
 264 (define (url->cache-file-path-v2 uri)
 265   (build-path cache-object-dir (uri-encode (url->string uri))))
 266
 267 (define url->cache-object-path url->cache-file-path-v2)
 268
 269 (: cache-object-filename->url (-> Path-String Url))
 270 (define (cache-object-filename->url name)
 271   (string->url (uri-decode (path->string name))))
 272
 273 (define (url->cache-etag-path uri)
 274   (build-path cache-dir "etags" (uri-encode (url->string uri))))
 275
 276 (define (url->cache-lmod-path uri)
 277   (build-path cache-dir "lmods" (uri-encode (url->string uri))))
 278
 279 ; TODO Return Option
 280 (: uri-read-cached (-> Url String))
 281 (define (uri-read-cached uri)
 282   (define path-v1 (url->cache-file-path-v1 uri))
 283   (define path-v2 (url->cache-file-path-v2 uri))
 284   (when (file-exists? path-v1)
 285     (rename-file-or-directory path-v1 path-v2 #t))
 286   (if (file-exists? path-v2)
 287       (file->string path-v2)
 288       (begin
 289         (log-warning "Cache file not found for URI: ~a" (url->string uri))
 290         "")))
 291
 292 (: uri? (-> String Boolean))
 293 (define (uri? str)
 294   (regexp-match? #rx"^[a-z]+://.*" (string-downcase str)))
 295
 296 (: str->peer (String (Option Peer)))
 297 (define (str->peer str)
 298   (log-debug "Parsing peer string: ~v" str)
 299   (with-handlers*
 300     ([exn:fail?
 301        (λ (e)
 302           (log-error "Invalid URI in string: ~v, exn: ~v" str e)
 303           #f)])
 304     (match (string-split str)
 305       [(list u)   #:when (uri? u) (Peer #f  (string->url u))]
 306       [(list n u) #:when (uri? u) (Peer  n  (string->url u))]
 307       [_
 308         (log-error "Invalid peer string: ~v" str)
 309         #f])))
 310
 311
 312 (: filter-comments (-> (Listof String) (Listof String)))
 313 (define (filter-comments lines)
 314   (filter-not (λ (line) (string-prefix? line "#")) lines))
 315
 316 (: str->peers (-> String (Listof Peer)))
 317 (define (str->peers str)
 318   (filter-map str->peer (filter-comments (str->lines str))))
 319
 320 (: peers->file (-> (Listof Peers) Path-String Void))
 321 (define (peers->file peers path)
 322   (display-lines-to-file
 323     (map (match-lambda
 324            [(Peer n u)
 325             (format "~a~a" (if n (format "~a " n) "") (url->string u))])
 326          peers)
 327     path
 328     #:exists 'replace))
 329
 330 (: file->peers (-> Path-String (Listof Peer)))
 331 (define (file->peers file-path)
 332   (if (file-exists? file-path)
 333       (str->peers (file->string file-path))
 334       (begin
 335         (log-warning "File does not exist: ~v" (path->string file-path))
 336         '())))
 337
 338 (define re-rfc2822
 339   #px"^(Mon|Tue|Wed|Thu|Fri|Sat|Sun), ([0-9]{2}) (Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec) ([0-9]{4}) ([0-2][0-9]):([0-6][0-9]):([0-6][0-9]) GMT")
 340
 341 (: b->n (-> Bytes (Option Number)))
 342 (define (b->n b)
 343   (string->number (bytes->string/utf-8 b)))
 344
 345 (: mon->num (-> Bytes Natural))
 346 (define/match (mon->num mon)
 347   [(#"Jan")  1]
 348   [(#"Feb")  2]
 349   [(#"Mar")  3]
 350   [(#"Apr")  4]
 351   [(#"May")  5]
 352   [(#"Jun")  6]
 353   [(#"Jul")  7]
 354   [(#"Aug")  8]
 355   [(#"Sep")  9]
 356   [(#"Oct") 10]
 357   [(#"Nov") 11]
 358   [(#"Dec") 12])
 359
 360 (: rfc2822->epoch (-> Bytes (Option Nonnegative-Integer)))
 361 (define (rfc2822->epoch timestamp)
 362   (match (regexp-match re-rfc2822 timestamp)
 363     [(list _ _ dd mo yyyy HH MM SS)
 364      #:when (and dd mo yyyy HH MM SS)
 365      (find-seconds (b->n SS)
 366                    (b->n MM)
 367                    (b->n HH)
 368                    (b->n dd)
 369                    (mon->num mo)
 370                    (b->n yyyy)
 371                    #f)]
 372     [_
 373       #f]))
 374
 375 (: user-agent String)
 376 (define user-agent
 377   (let*
 378     ([prog-name      "tt"]
 379      [prog-version   (info:#%info-lookup 'version)]
 380      [prog-uri       "https://github.com/xandkar/tt"]
 381      [user-peer-file (build-path tt-home-dir "me")]
 382      [user
 383        (if (file-exists? user-peer-file)
 384            (match (first (file->peers user-peer-file))
 385              [(Peer #f u) (format "+~a"      (url->string u)  )]
 386              [(Peer  n u) (format "+~a; @~a" (url->string u) n)])
 387            (format "+~a" prog-uri))])
 388     (format "~a/~a (~a)" prog-name prog-version user)))
 389
 390 (: header-get (-> (Listof Bytes) Bytes (Option Bytes)))
 391 (define (header-get headers name)
 392   (match (filter-map (curry extract-field name) headers)
 393     [(list val) val]
 394     [_           #f]))
 395
 396 (: uri-download (-> Positive-Float Url Void))
 397 (define (uri-download timeout u)
 398   (define cached-object-path (url->cache-object-path u))
 399   (define cached-etag-path (url->cache-etag-path u))
 400   (define cached-lmod-path (url->cache-lmod-path u))
 401   (define u-str (url->string u))
 402   (log-debug "uri-download ~v into ~v" u-str cached-object-path)
 403   (define timeout-chan (make-channel))
 404   (define result-chan (make-channel))
 405   (define timeout-thread
 406     (thread (λ ()
 407                ; Doing this instead of sync/timeout to distinguish error values,
 408                ; rather than just have #f to work with.
 409                (sleep timeout)
 410                (channel-put timeout-chan (cons 'error 'timeout)))))
 411   (define result-thread
 412     (thread (λ ()
 413                ; XXX We timeout getting a response, but body download could
 414                ; also take a long time and we might want to time that out as
 415                ; well, but then we may end-up with partially downloaded
 416                ; objects. But that could happen anyway if the server drops the
 417                ; connection for whatever reason.
 418                ;
 419                ; Maybe that is OK once we start treating the
 420                ; downloaded object as an addition to the stored set of
 421                ; messages, rather than the final set of messages.
 422
 423                ; TODO message db
 424                ; - 1st try can just be an in-memory set that gets written-to
 425                ;   and read-from disk as a whole.
 426                (define result
 427                  (with-handlers
 428                    ([exn:fail? (λ (e) (cons 'error (cons 'net-error e)))])
 429                    (define-values (status-line headers body-input)
 430                      (http-sendrecv/url
 431                        u
 432                        #:headers (list (format "User-Agent: ~a" user-agent))))
 433                    (cons 'ok (Resp status-line headers body-input))))
 434                (channel-put result-chan result))))
 435   (define result
 436     (sync timeout-chan
 437           result-chan))
 438   (kill-thread result-thread)
 439   (kill-thread timeout-thread)
 440   (match result
 441     [(cons 'error 'timeout)
 442      (log-error "Download failed: timeout. URL:~v" u-str)]
 443     [(cons 'error (cons 'net-error e))
 444      (log-error "Download failed. Network error. URL:~v  EXN:~v" u-str e)]
 445     [(cons 'ok (Resp status-line headers body-input))
 446      (log-debug "headers: ~v" headers)
 447      (log-debug "status-line: ~v" status-line)
 448      (define status
 449        (string->number (second (string-split (bytes->string/utf-8 status-line)))))
 450      (log-debug "status: ~v" status)
 451      ; TODO Handle redirects
 452      (match status
 453        [200
 454          (let* ([etag      (header-get headers #"ETag")]
 455                 [lmod      (header-get headers #"Last-Modified")]
 456                 [lmod-curr (if lmod (rfc2822->epoch lmod) #f)]
 457                 [lmod-prev (if (file-exists? cached-lmod-path)
 458                                (rfc2822->epoch (file->bytes cached-lmod-path))
 459                                #f)])
 460            (log-debug "lmod-curr:~v lmod-prev:~v" lmod-curr lmod-prev)
 461            (unless (or (and etag
 462                             (file-exists? cached-etag-path)
 463                             (bytes=? etag (file->bytes cached-etag-path))
 464                             (begin
 465                               (log-info "ETags match, skipping the rest of ~v" u-str)
 466                               #t))
 467                        (and lmod-curr
 468                             lmod-prev
 469                             (<= lmod-curr lmod-prev)
 470                             (begin
 471                               (log-info "Last-Modified <= current skipping the rest of ~v" u-str)
 472                               #t)))
 473              (begin
 474                (log-info
 475                  "Downloading the rest of ~v. ETag: ~a, Last-Modified: ~v"
 476                  u-str etag lmod)
 477                (make-parent-directory* cached-object-path)
 478                (make-parent-directory* cached-etag-path)
 479                (make-parent-directory* cached-lmod-path)
 480                (call-with-output-file cached-object-path
 481                                       (curry copy-port body-input)
 482                                       #:exists 'replace)
 483                (when etag
 484                  (display-to-file etag cached-etag-path #:exists 'replace))
 485                (when lmod
 486                  (display-to-file lmod cached-lmod-path #:exists 'replace)))))]
 487        [_
 488          (log-error "HTTP error URL:~a  status:~a" u-str status)])
 489      (close-input-port body-input)]))
 490
 491 (: timeline-print (-> Out-Format (Listof Msg) Void))
 492 (define (timeline-print out-format timeline)
 493   (void (foldl (match-lambda**
 494                  [((and m (Msg _ _ nick _ _ _)) (cons prev-nick i))
 495                   (let ([i (if (equal? prev-nick nick) i (+ 1 i))])
 496                     (msg-print out-format i m)
 497                     (cons nick i))])
 498                (cons "" 0)
 499                timeline)))
 500
 501 (: peer->msgs (-> Peer (Listof Msg)))
 502 (define (peer->msgs f)
 503   (match-define (Peer nick uri) f)
 504   (log-info "Reading peer nick:~v uri:~v" nick (url->string uri))
 505   (str->msgs nick uri (uri-read-cached uri)))
 506
 507 (: peer-download (-> Positive-Float Peer Void))
 508 (define (peer-download timeout peer)
 509   (match-define (Peer nick uri) peer)
 510   (define u (url->string uri))
 511   (log-info "Download BEGIN uri:~a" u)
 512   (define-values (_result _tm-cpu-ms tm-real-ms _tm-gc-ms)
 513     (time-apply uri-download (list timeout uri)))
 514   (log-info "Download END in ~a seconds, uri: ~a" (/ tm-real-ms 1000.0) u))
 515
 516 (: timeline-download (-> Integer Positive-Float (Listof Peer) Void))
 517 (define (timeline-download num-workers timeout peers)
 518   ; TODO No need for map - can just iter
 519   (void (concurrent-filter-map num-workers (λ (p) (peer-download timeout p)) peers)))
 520
 521 (: uniq (∀ (α) (-> (Listof α) (Listof α))))
 522 (define (uniq xs)
 523   (set->list (list->set xs)))
 524
 525 (: peers->timeline (-> (listof Peer) (listof Msg)))
 526 (define (peers->timeline peers)
 527   (append* (filter-map peer->msgs peers)))
 528
 529 (: timeline-sort (-> (listof Msg) timeline-order (Listof Msgs)))
 530 (define (timeline-sort msgs order)
 531   (define cmp (match order
 532                 ['old->new <]
 533                 ['new->old >]))
 534   (sort msgs (λ (a b) (cmp (Msg-ts-epoch a)
 535                            (Msg-ts-epoch b)))))
 536
 537 (: paths->peers (-> (Listof String) (Listof Peer)))
 538 (define (paths->peers paths)
 539   (let* ([paths (match paths
 540                   ['()
 541                    (let ([peer-refs-file (build-path tt-home-dir "peers")])
 542                      (log-debug
 543                        "No peer ref file paths provided, defaulting to ~v"
 544                        (path->string peer-refs-file))
 545                      (list peer-refs-file))]
 546                   [paths
 547                     (log-debug "Peer ref file paths provided: ~v" paths)
 548                     (map string->path paths)])]
 549          [peers (append* (map file->peers paths))])
 550     (log-info "Read-in ~a peers." (length peers))
 551     (uniq peers)))
 552
 553 (: mentioned-peers-in-cache (-> (Listof Peer)))
 554 (define (mentioned-peers-in-cache)
 555   (define msgs
 556     (append* (map (λ (filename)
 557                      (define path (build-path cache-object-dir filename))
 558                      (define size (/ (file-size path) 1000000.0))
 559                      (log-info "BEGIN parsing ~a MB from file: ~v"
 560                                size
 561                                (path->string path))
 562                      (define t0 (current-inexact-milliseconds))
 563                      (define m (filter-map
 564                                  (λ (line)
 565                                     (str->msg #f (cache-object-filename->url filename) line))
 566                                  (filter-comments
 567                                    (file->lines path))))
 568                      (define t1 (current-inexact-milliseconds))
 569                      (log-info "END parsing ~a MB in ~a seconds from file: ~v."
 570                                size
 571                                (* 0.001 (- t1 t0))
 572                                (path->string path))
 573                      (when (empty? m)
 574                        (log-warning "No messages found in ~a" (path->string path)))
 575                      m)
 576                   (directory-list cache-object-dir))))
 577   (uniq (append* (map Msg-mentions msgs))))
 578
 579 (: log-writer-stop (-> Thread Void))
 580 (define (log-writer-stop log-writer)
 581   (log-message (current-logger) 'fatal 'stop "Exiting." #f)
 582   (thread-wait log-writer))
 583
 584 (: log-writer-start (-> Log-Level Thread))
 585 (define (log-writer-start level)
 586   (let* ([logger
 587            (make-logger #f #f level #f)]
 588          [log-receiver
 589            (make-log-receiver logger level)]
 590          [log-writer
 591            (thread
 592              (λ ()
 593                 (parameterize
 594                   ([date-display-format 'iso-8601])
 595                   (let loop ()
 596                     (match-define (vector level msg _ topic) (sync log-receiver))
 597                     (unless (equal? topic 'stop)
 598                       (eprintf "~a [~a] ~a~n" (date->string (current-date) #t) level msg)
 599                       (loop))))))])
 600     (current-logger logger)
 601     log-writer))
 602
 603 (module+ main
 604   (let ([log-level 'info])
 605     (command-line
 606       #:program
 607       "tt"
 608       #:once-each
 609       [("-d" "--debug")
 610        "Enable debug log level."
 611        (set! log-level 'debug)]
 612       #:help-labels
 613       ""
 614       "and <command> is one of"
 615       "r, read     : Read the timeline (offline operation)."
 616       "d, download : Download the timeline."
 617       ; TODO Add path dynamically
 618       "u, upload   : Upload your twtxt file (alias to execute ~/.tt/upload)."
 619       "c, crawl    : Discover new peers mentioned by known peers (offline operation)."
 620       ""
 621       #:args (command . args)
 622       (define log-writer (log-writer-start log-level))
 623       (current-command-line-arguments (list->vector args))
 624       (match command
 625         [(or "d" "download")
 626          ; Initially, 15 was fastest out of the tried: 1, 5, 10, 20.  Then I
 627          ; started noticing significant slowdowns. Reducing to 5 seems to help.
 628          (let ([num-workers 5]
 629                [timeout     10.0])
 630            (command-line
 631              #:program
 632              "tt download"
 633              #:once-each
 634              [("-j" "--jobs")
 635               njobs "Number of concurrent jobs."
 636               (set! num-workers (string->number njobs))]
 637              [("-t" "--timeout")
 638               seconds "Timeout seconds per request."
 639               (set! timeout (string->number seconds))]
 640              #:args file-paths
 641              (let ([peers (paths->peers file-paths)])
 642                (define-values (_res _cpu real-ms _gc)
 643                  (time-apply timeline-download (list num-workers timeout peers)))
 644                (log-info "Downloaded timelines from ~a peers in ~a seconds."
 645                          (length peers)
 646                          (/ real-ms 1000.0)))))]
 647         [(or "u" "upload")
 648          (command-line
 649            #:program
 650            "tt upload"
 651            #:args ()
 652            (if (system (path->string (build-path tt-home-dir "upload")))
 653                (exit 0)
 654                (exit 1)))]
 655         [(or "r" "read")
 656          (let ([out-format 'multi-line]
 657                [order      'old->new]
 658                [ts-min     #f]
 659                [ts-max     #f])
 660            (command-line
 661              #:program
 662              "tt read"
 663              #:once-each
 664              [("-r" "--rev")
 665               "Reverse displayed timeline order."
 666               (set! order 'new->old)]
 667              [("-m" "--min")
 668               m "Earliest time to display (ignore anything before it)."
 669               (set! ts-min (rfc3339->epoch m))]
 670              [("-x" "--max")
 671               x "Latest time to display (ignore anything after it)."
 672               (set! ts-max (rfc3339->epoch x))]
 673              #:once-any
 674              [("-s" "--short")
 675               "Short output format"
 676               (set! out-format 'single-line)]
 677              [("-l" "--long")
 678               "Long output format"
 679               (set! out-format 'multi-line)]
 680              #:args file-paths
 681              (let* ([peers
 682                       (paths->peers file-paths)]
 683                     [timeline
 684                       (timeline-sort (peers->timeline peers) order)]
 685                     [timeline
 686                       (filter (λ (m) (and (if ts-min (>= (Msg-ts-epoch m)
 687                                                          ts-min)
 688                                               #t)
 689                                           (if ts-max (<= (Msg-ts-epoch m)
 690                                                          ts-max)
 691                                               #t)))
 692                               timeline)])
 693                (timeline-print out-format timeline))))]
 694         [(or "c" "crawl")
 695          (command-line
 696            #:program
 697            "tt crawl"
 698            #:args ()
 699            (let* ([peers-sort
 700                     (λ (peers) (sort peers (match-lambda**
 701                                              [((Peer n1 _) (Peer n2 _))
 702                                               (string<? (if n1 n1 "")
 703                                                         (if n2 n2 ""))])))]
 704                   [peers-all-file
 705                     (build-path tt-home-dir "peers-all")]
 706                   [peers-mentioned-file
 707                     (build-path tt-home-dir "peers-mentioned")]
 708                   [peers-mentioned-curr
 709                     (mentioned-peers-in-cache)]
 710                   [peers-mentioned-prev
 711                     (file->peers peers-mentioned-file)]
 712                   [peers-mentioned
 713                     (peers-sort (uniq (append peers-mentioned-prev
 714                                               peers-mentioned-curr)))]
 715                   [peers-all-prev
 716                     (file->peers peers-all-file)]
 717                   [peers-all
 718                     (list->set (append peers-mentioned
 719                                        peers-all-prev))]
 720                   [peers-discovered
 721                     (set-subtract peers-all (list->set peers-all-prev))]
 722                   [peers-all
 723                     (peers-sort (set->list peers-all))])
 724              (log-info "Known peers mentioned: ~a" (length peers-mentioned))
 725              (log-info "Known peers total: ~a" (length peers-all))
 726              (log-info "Discovered ~a new peers:~n~a"
 727                        (set-count peers-discovered)
 728                        (pretty-format (map
 729                                         (λ (p) (cons (Peer-nick p)
 730                                                      (url->string (Peer-uri p))))
 731                                         (set->list peers-discovered))))
 732              (peers->file peers-mentioned
 733                           peers-mentioned-file)
 734              (peers->file peers-all
 735                           peers-all-file)))]
 736         [command
 737           (eprintf "Error: invalid command: ~v\n" command)
 738           (eprintf "Please use the \"--help\" option to see a list of available commands.\n")
 739           (exit 1)])
 740       (log-writer-stop log-writer))))