tt.rkt

   1 #lang typed/racket/no-check
   2
   3 (require openssl/sha1)
   4 (require racket/date)
   5 (require
   6   net/head
   7   net/uri-codec
   8   net/url)
   9
  10 (require (prefix-in info: "info.rkt"))
  11
  12 (module+ test
  13   (require rackunit))
  14
  15 (define-type Url
  16   net/url-structs:url)
  17
  18 (define-type Out-Format
  19   (U 'single-line
  20      'multi-line))
  21
  22 (define-type Timeline-Order
  23   (U 'old->new
  24      'new->old))
  25
  26 (struct Msg
  27         ([ts-epoch   : Integer]
  28          [ts-orig    : String]
  29          [nick       : (Option String)]
  30          [uri        : Url]
  31          [text       : String]
  32          [mentions   : (Listof Peer)]))
  33
  34 (struct Peer
  35         ([nick : (Option String)]
  36          [uri  : Url])
  37         #:transparent)
  38
  39 (: tt-home-dir Path-String)
  40 (define tt-home-dir (build-path (expand-user-path "~") ".tt"))
  41
  42 (: concurrent-filter-map (∀ (α β) (-> Natural (-> α β) (Listof α) (Listof β))))
  43 (define (concurrent-filter-map num-workers f xs)
  44   ; TODO preserve order of elements OR communicate that reorder is expected
  45   ; TODO switch from mailboxes to channels
  46   (define (make-worker id f)
  47     (define parent (current-thread))
  48     (λ ()
  49        (define self : Thread (current-thread))
  50        (: work (∀ (α) (-> α)))
  51        (define (work)
  52          (thread-send parent (cons 'next self))
  53          (match (thread-receive)
  54            ['done          (thread-send parent (cons 'exit id))]
  55            [(cons 'unit x) (begin
  56                              (define y (f x))
  57                              (when y (thread-send parent (cons 'result y)))
  58                              (work))]))
  59        (work)))
  60   (: dispatch (∀ (α β) (-> (Listof Nonnegative-Integer) (Listof α) (Listof β))))
  61   (define (dispatch ws xs ys)
  62     (if (empty? ws)
  63         ys
  64         (match (thread-receive)
  65           [(cons 'exit w)   (dispatch (remove w ws =) xs ys)]
  66           [(cons 'result y) (dispatch ws xs (cons y ys))]
  67           [(cons 'next thd) (match xs
  68                               ['()         (begin
  69                                              (thread-send thd 'done)
  70                                              (dispatch ws xs ys))]
  71                               [(cons x xs) (begin
  72                                              (thread-send thd (cons 'unit x))
  73                                              (dispatch ws xs ys))])])))
  74   (define workers (range num-workers))
  75   (define threads (map (λ (id) (thread (make-worker id f))) workers))
  76   (define results (dispatch workers xs '()))
  77   (for-each thread-wait threads)
  78   results)
  79
  80 (module+ test
  81   (let* ([f        (λ (x) (if (even? x) x #f))]
  82          [xs       (range 11)]
  83          [actual   (sort (concurrent-filter-map 10 f xs) <)]
  84          [expected (sort (           filter-map    f xs) <)])
  85     (check-equal? actual expected "concurrent-filter-map")))
  86
  87 (: msg-print (-> Out-Format Integer Msg Void))
  88 (define msg-print
  89   (let* ([colors (vector 36 33)]
  90          [n      (vector-length colors)])
  91     (λ (out-format color-i msg)
  92        (let ([color (vector-ref colors (modulo color-i n))]
  93              [nick  (Msg-nick msg)]
  94              [uri   (url->string (Msg-uri msg))]
  95              [text  (Msg-text msg)]
  96              [mentions (Msg-mentions msg)])
  97          (match out-format
  98            ['single-line
  99             (let ([nick (if nick nick uri)])
 100               (printf "~a  \033[1;37m<~a>\033[0m  \033[0;~am~a\033[0m~n"
 101                       (parameterize
 102                         ([date-display-format 'iso-8601])
 103                         (date->string (seconds->date (Msg-ts-epoch msg)) #t))
 104                       nick color text))]
 105            ['multi-line
 106             (let ([nick (if nick (string-append nick " ") "")])
 107               (printf "~a (~a)~n\033[1;37m<~a~a>\033[0m~n\033[0;~am~a\033[0m~n~n"
 108                       (parameterize
 109                         ([date-display-format 'rfc2822])
 110                         (date->string (seconds->date (Msg-ts-epoch msg)) #t))
 111                       (Msg-ts-orig msg)
 112                       nick uri color text))])))))
 113
 114 (: rfc3339->epoch (-> String (Option Nonnegative-Integer)))
 115 (define rfc3339->epoch
 116   (let ([re (pregexp "^([0-9]{4})-([0-9]{2})-([0-9]{2})T([0-9]{2}):([0-9]{2})(:([0-9]{2}))?(\\.[0-9]+)?(Z|([+-])([0-9]{1,2}):?([0-9]{2}))?$")])
 117     (λ (ts)
 118        (match (regexp-match re ts)
 119          [(list _wholething yyyy mm dd HH MM _:SS SS _fractional tz-whole tz-sign tz-HH tz-MM)
 120           (let*
 121             ([tz-offset
 122                (match* (tz-whole tz-sign tz-HH tz-MM)
 123                  [("Z" #f #f #f)
 124                   0]
 125                  [(_  (or "-" "+") (? identity h)  (? identity m))
 126                   (let ([h (string->number h)]
 127                         [m (string->number m)]
 128                         ; Reverse to get back to UTC:
 129                         [op (match tz-sign ["+" -] ["-" +])])
 130                     (op 0 (+ (* 60 m) (* 60 (* 60 h)))))]
 131                  [(a b c d)
 132                   (log-warning "Impossible TZ string: ~v, components: ~v ~v ~v ~v" tz-whole a b c d)
 133                   0])]
 134              [ts-orig ts]
 135              [local-time? #f]
 136              [ts-epoch (find-seconds (if SS (string->number SS) 0)
 137                                      (string->number MM)
 138                                      (string->number HH)
 139                                      (string->number dd)
 140                                      (string->number mm)
 141                                      (string->number yyyy)
 142                                      local-time?)])
 143             (+ ts-epoch tz-offset))]
 144          [_
 145            (log-error "Invalid timestamp: ~v" ts)
 146            #f]))))
 147
 148 (: str->msg (-> (Option String) Url String (Option Msg)))
 149 (define str->msg
 150   (let ([re (pregexp "^([^\\s\t]+)[\\s\t]+(.*)$")])
 151     (λ (nick uri str)
 152        (with-handlers*
 153          ([exn:fail?
 154             (λ (e)
 155                (log-error
 156                  "Failed to parse msg: ~v, from: ~v, at: ~v, because: ~v"
 157                  str nick (url->string uri) e)
 158                #f)])
 159          (match (regexp-match re str)
 160            [(list _wholething ts-orig text)
 161             (let ([ts-epoch (rfc3339->epoch ts-orig)])
 162               (if ts-epoch
 163                   (let ([mentions
 164                           (filter-map
 165                             (λ (m) (match (regexp-match #px"@<([^>]+)>" m)
 166                                      [(list _wholething nick-uri)
 167                                       (str->peer nick-uri)]))
 168                             (regexp-match* #px"@<[^\\s]+([\\s]+)?[^>]+>" text))])
 169                     (Msg ts-epoch ts-orig nick uri text mentions))
 170                   (begin
 171                     (log-error
 172                       "Msg rejected due to invalid timestamp: ~v, nick:~v, uri:~v"
 173                       str nick (url->string uri))
 174                     #f)))]
 175            [_
 176              (log-debug "Non-msg line from nick:~v, line:~a" nick str)
 177              #f])))))
 178
 179 (module+ test
 180   ; TODO Test for when missing-nick case
 181   (let* ([tzs (for*/list ([d '("-" "+")]
 182                           [h '("5" "05")]
 183                           [m '("00" ":00" "57" ":57")])
 184                          (string-append d h m))]
 185          [tzs (list* "" "Z" tzs)])
 186     (for* ([n   '("fake-nick")]
 187            [u   '("fake-uri")]
 188            [s   '("" ":10")]
 189            [f   '("" ".1337")]
 190            [z   tzs]
 191            [sep (list "\t" " ")]
 192            [txt '("foo bar baz" "'jaz poop bear giraffe / tea" "@*\"``")])
 193           (let* ([ts (string-append "2020-11-18T22:22"
 194                                     (if (non-empty-string? s) s ":00")
 195                                     z)]
 196                  [m  (str->msg n u (string-append ts sep txt))])
 197             (check-not-false m)
 198             (check-equal? (Msg-nick m) n)
 199             (check-equal? (Msg-uri m) u)
 200             (check-equal? (Msg-text m) txt)
 201             (check-equal? (Msg-ts-orig m) ts (format "Given: ~v" ts))
 202             )))
 203
 204   (let* ([ts       "2020-11-18T22:22:09-0500"]
 205          [tab      "    "]
 206          [text     "Lorem ipsum"]
 207          [nick     "foo"]
 208          [uri      "bar"]
 209          [actual   (str->msg nick uri (string-append ts tab text))]
 210          [expected (Msg 1605756129 ts nick uri text)])
 211     (check-equal?
 212       (Msg-ts-epoch actual)
 213       (Msg-ts-epoch expected)
 214       "str->msg ts-epoch")
 215     (check-equal?
 216       (Msg-ts-orig actual)
 217       (Msg-ts-orig expected)
 218       "str->msg ts-orig")
 219     (check-equal?
 220       (Msg-nick actual)
 221       (Msg-nick expected)
 222       "str->msg nick")
 223     (check-equal?
 224       (Msg-uri actual)
 225       (Msg-uri expected)
 226       "str->msg uri")
 227     (check-equal?
 228       (Msg-text actual)
 229       (Msg-text expected)
 230       "str->msg text")))
 231
 232 (: str->lines (-> String (Listof String)))
 233 (define (str->lines str)
 234   (string-split str (regexp "[\r\n]+")))
 235
 236 (module+ test
 237   (check-equal? (str->lines "abc\ndef\n\nghi") '("abc" "def" "ghi")))
 238
 239 (: str->msgs (-> (Option String) Url String (Listof Msg)))
 240 (define (str->msgs nick uri str)
 241   (filter-map (λ (line) (str->msg nick uri line)) (filter-comments (str->lines str))))
 242
 243 (: cache-dir Path-String)
 244 (define cache-dir (build-path tt-home-dir "cache"))
 245
 246 (define cache-object-dir (build-path cache-dir "objects"))
 247
 248 (: url->cache-file-path-v1 (-> Url Path-String))
 249 (define (url->cache-file-path-v1 uri)
 250   (define (hash-sha1 str) : (-> String String)
 251     (define in (open-input-string str))
 252     (define digest (sha1 in))
 253     (close-input-port in)
 254     digest)
 255   (build-path cache-object-dir (hash-sha1 (url->string uri))))
 256
 257 (: url->cache-file-path-v2 (-> Url Path-String))
 258 (define (url->cache-file-path-v2 uri)
 259   (build-path cache-object-dir (uri-encode (url->string uri))))
 260
 261 (define url->cache-object-path url->cache-file-path-v2)
 262
 263 (define (url->cache-etag-path uri)
 264   (build-path cache-dir "etags" (uri-encode (url->string uri))))
 265
 266 (define (url->cache-lmod-path uri)
 267   (build-path cache-dir "lmods" (uri-encode (url->string uri))))
 268
 269 ; TODO Return Option
 270 (: uri-read-cached (-> Url String))
 271 (define (uri-read-cached uri)
 272   (define path-v1 (url->cache-file-path-v1 uri))
 273   (define path-v2 (url->cache-file-path-v2 uri))
 274   (when (file-exists? path-v1)
 275     (rename-file-or-directory path-v1 path-v2 #t))
 276   (if (file-exists? path-v2)
 277       (file->string path-v2)
 278       (begin
 279         (log-warning "Cache file not found for URI: ~a" (url->string uri))
 280         "")))
 281
 282 (: str->peer (String (Option Peer)))
 283 (define (str->peer str)
 284   (log-debug "Parsing peer string: ~v" str)
 285   (with-handlers*
 286     ([exn:fail?
 287        (λ (e)
 288           (log-error "Invalid URI in string: ~v, exn: ~v" str e)
 289           #f)])
 290     (match (string-split str)
 291       [(list u)   (Peer #f  (string->url u))]
 292       [(list n u) (Peer  n  (string->url u))]
 293       [_
 294         (log-error "Invalid peer string: ~v" str)
 295         #f])))
 296
 297
 298 (: filter-comments (-> (Listof String) (Listof String)))
 299 (define (filter-comments lines)
 300   (filter-not (λ (line) (string-prefix? line "#")) lines))
 301
 302 (: str->peers (-> String (Listof Peer)))
 303 (define (str->peers str)
 304   (filter-map str->peer (filter-comments (str->lines str))))
 305
 306 (: file->peers (-> Path-String (Listof Peer)))
 307 (define (file->peers file-path)
 308   (if (file-exists? file-path)
 309       (str->peers (file->string file-path))
 310       (begin
 311         (log-error "File does not exist: ~v" (path->string file-path))
 312         '())))
 313
 314 (: user-agent String)
 315 (define user-agent
 316   (let*
 317     ([prog-name      "tt"]
 318      [prog-version   (info:#%info-lookup 'version)]
 319      [prog-uri       "https://github.com/xandkar/tt"]
 320      [user-peer-file (build-path tt-home-dir "me")]
 321      [user
 322        (if (file-exists? user-peer-file)
 323            (match (first (file->peers user-peer-file))
 324              [(Peer #f u) (format "+~a"      (url->string u)  )]
 325              [(Peer  n u) (format "+~a; @~a" (url->string u) n)])
 326            (format "+~a" prog-uri))])
 327     (format "~a/~a (~a)" prog-name prog-version user)))
 328
 329 (: header-get (-> (Listof Bytes) Bytes (Option Bytes)))
 330 (define (header-get headers name)
 331   (match (filter-map (curry extract-field name) headers)
 332     [(list val) val]
 333     [_           #f]))
 334
 335 (: uri-download (-> Url Void))
 336 (define (uri-download u)
 337   (define cached-object-path (url->cache-object-path u))
 338   (define cached-etag-path (url->cache-etag-path u))
 339   (define cached-lmod-path (url->cache-lmod-path u))
 340   (log-debug "uri-download ~v into ~v" u cached-object-path)
 341   (define-values (status-line headers body-input)
 342     ; TODO Timeout. Currently hangs on slow connections.
 343     (http-sendrecv/url u #:headers (list (format "User-Agent: ~a" user-agent))))
 344   (log-debug "headers: ~v" headers)
 345   (log-debug "status-line: ~v" status-line)
 346   (define status
 347     (string->number (second (string-split (bytes->string/utf-8 status-line)))))
 348   (log-debug "status: ~v" status)
 349   ; TODO Handle redirects
 350   (match status
 351     [200
 352       (let ([etag (header-get headers #"ETag")]
 353             [lmod (header-get headers #"Last-Modified")])
 354         (if (and etag
 355                  (file-exists? cached-etag-path)
 356                  (bytes=? etag (file->bytes cached-etag-path)))
 357             (log-info "ETags match, skipping the rest of ~v" (url->string u))
 358             (begin
 359               (log-info
 360                 "Downloading the rest of ~v. ETag: ~a, Last-Modified: ~v"
 361                 (url->string u) etag lmod)
 362               (make-parent-directory* cached-object-path)
 363               (make-parent-directory* cached-etag-path)
 364               (make-parent-directory* cached-lmod-path)
 365               (call-with-output-file cached-object-path
 366                                      (curry copy-port body-input)
 367                                      #:exists 'replace)
 368               (when etag
 369                 (display-to-file etag cached-etag-path #:exists 'replace))
 370               (when lmod
 371                 (display-to-file etag cached-lmod-path #:exists 'replace))))
 372         (close-input-port body-input))]
 373     [_
 374       (raise status)]))
 375
 376 (: timeline-print (-> Out-Format (Listof Msg) Void))
 377 (define (timeline-print out-format timeline)
 378   (void (foldl (match-lambda**
 379                  [((and m (Msg _ _ nick _ _ _)) (cons prev-nick i))
 380                   (let ([i (if (equal? prev-nick nick) i (+ 1 i))])
 381                     (msg-print out-format i m)
 382                     (cons nick i))])
 383                (cons "" 0)
 384                timeline)))
 385
 386 (: peer->msgs (-> Peer (Listof Msg)))
 387 (define (peer->msgs f)
 388   (match-define (Peer nick uri) f)
 389   (log-info "Reading peer nick:~v uri:~v" nick (url->string uri))
 390   (str->msgs nick uri (uri-read-cached uri)))
 391
 392 (: peer-download (-> Peer Void))
 393 (define (peer-download f)
 394   (match-define (Peer nick uri) f)
 395   (define u (url->string uri))
 396   (log-info "Downloading peer uri:~a" u)
 397   (with-handlers
 398     ([exn:fail?
 399        (λ (e)
 400           (log-error "Network error nick:~v uri:~v  exn:~v" nick u e)
 401           #f)]
 402      [integer?
 403        (λ (status)
 404           (log-error "HTTP error nick:~v uri:~a  status:~a" nick u status)
 405           #f)])
 406     (define-values (_result _tm-cpu-ms tm-real-ms _tm-gc-ms)
 407       (time-apply uri-download (list uri)))
 408     (log-info "Peer downloaded in ~a seconds, uri: ~a" (/ tm-real-ms 1000.0) u)))
 409
 410 (: timeline-download (-> Integer (Listof Peer) Void))
 411 (define (timeline-download num-workers peers)
 412   ; TODO No need for map - can just iter
 413   (void (concurrent-filter-map num-workers peer-download peers)))
 414
 415 ; TODO timeline contract : time-sorted list of messages
 416 (: timeline-read (-> Timeline-Order (Listof Peer) (Listof Msg)))
 417 (define (timeline-read order peers)
 418   (define cmp (match order
 419                 ['old->new <]
 420                 ['new->old >]))
 421   (sort (append* (filter-map peer->msgs peers))
 422         (λ (a b) (cmp (Msg-ts-epoch a) (Msg-ts-epoch b)))))
 423
 424 (: paths->peers (-> (Listof String) (Listof Peer)))
 425 (define (paths->peers paths)
 426   (let* ([paths (match paths
 427                   ['()
 428                    (let ([peer-refs-file (build-path tt-home-dir "peers")])
 429                      (log-debug
 430                        "No peer ref file paths provided, defaulting to ~v"
 431                        (path->string peer-refs-file))
 432                      (list peer-refs-file))]
 433                   [paths
 434                     (log-debug "Peer ref file paths provided: ~v" paths)
 435                     (map string->path paths)])]
 436          [peers (append* (map file->peers paths))])
 437     (log-info "Read-in ~a peers." (length peers))
 438     peers))
 439
 440 (: log-writer-stop (-> Thread Void))
 441 (define (log-writer-stop log-writer)
 442   (log-message (current-logger) 'fatal 'stop "Exiting." #f)
 443   (thread-wait log-writer))
 444
 445 (: log-writer-start (-> Log-Level Thread))
 446 (define (log-writer-start level)
 447   (let* ([logger
 448            (make-logger #f #f level #f)]
 449          [log-receiver
 450            (make-log-receiver logger level)]
 451          [log-writer
 452            (thread
 453              (λ ()
 454                 (parameterize
 455                   ([date-display-format 'iso-8601])
 456                   (let loop ()
 457                     (match-define (vector level msg _ topic) (sync log-receiver))
 458                     (unless (equal? topic 'stop)
 459                       (eprintf "~a [~a] ~a~n" (date->string (current-date) #t) level msg)
 460                       (loop))))))])
 461     (current-logger logger)
 462     log-writer))
 463
 464 (module+ main
 465   (let ([log-level 'info])
 466     (command-line
 467       #:program
 468       "tt"
 469       #:once-each
 470       [("-d" "--debug")
 471        "Enable debug log level."
 472        (set! log-level 'debug)]
 473       #:help-labels
 474       ""
 475       "and <command> is one of"
 476       "r, read i   : Read the timeline."
 477       "d, download : Download the timeline."
 478       ; TODO Add path dynamically
 479       "u, upload   : Upload your twtxt file (alias to execute ~/.tt/upload)."
 480       ""
 481       #:args (command . args)
 482       (define log-writer (log-writer-start log-level))
 483       (current-command-line-arguments (list->vector args))
 484       (match command
 485         [(or "d" "download")
 486          ; Initially, 15 was fastest out of the tried: 1, 5, 10, 20.  Then I
 487          ; started noticing significant slowdowns. Reducing to 5 seems to help.
 488          (let ([num-workers 5])
 489            (command-line
 490              #:program
 491              "tt download"
 492              #:once-each
 493              [("-j" "--jobs")
 494               njobs "Number of concurrent jobs."
 495               (set! num-workers (string->number njobs))]
 496              #:args file-paths
 497              (define-values (_res _cpu real-ms _gc)
 498                (time-apply timeline-download (list num-workers (paths->peers file-paths))))
 499              (log-info "Timeline downloaded in ~a seconds." (/ real-ms 1000.0))))]
 500         [(or "u" "upload")
 501          (command-line
 502            #:program
 503            "tt upload"
 504            #:args ()
 505            (if (system (path->string (build-path tt-home-dir "upload")))
 506                (exit 0)
 507                (exit 1)))]
 508         [(or "r" "read")
 509          (let ([out-format 'multi-line]
 510                [order      'old->new])
 511            (command-line
 512              #:program
 513              "tt read"
 514              #:once-each
 515              [("-r" "--rev")
 516               "Reverse displayed timeline order."
 517               (set! order 'new->old)]
 518              #:once-any
 519              [("-s" "--short")
 520               "Short output format"
 521               (set! out-format 'single-line)]
 522              [("-l" "--long")
 523               "Long output format"
 524               (set! out-format 'multi-line)]
 525              #:args file-paths
 526              (timeline-print out-format (timeline-read order (paths->peers file-paths)))))])
 527       (log-writer-stop log-writer))))