tt

   1 #! /usr/bin/env racket
   2 ; vim: filetype=racket
   3
   4 ; TODO optional text wrap
   5 ; TODO write
   6 ; TODO caching (use cache by default, unless explicitly asked for update)
   7 ; TODO timeline limits
   8 ; TODO feed set operations (perhaps better done externally?)
   9 ; TODO timeline as a result of a query (feed set op + filter expressions)
  10 ; TODO named timelines
  11 ; TODO CLI params
  12 ; TODO config files
  13 ; TODO parse "following" from feed
  14 ; - following = <nick> <uri>
  15 ; TODO parse mentions:
  16 ; - @<source.nick source.url> | @<source.url>
  17 ; TODO highlight mentions
  18 ; TODO filter on mentions
  19 ; TODO highlight hashtags
  20 ; TODO filter on hashtags
  21 ; TODO hashtags as channels? initial hashtag special?
  22 ; TODO query language
  23 ; TODO console logger colors by level ('error)
  24 ; TODO file logger ('debug)
  25 ; TODO commands:
  26 ; - r | read
  27 ;   - see timeline ops above
  28 ; - w | write
  29 ;   - arg or stdin
  30 ;   - nick expand to URI
  31 ; - q | query
  32 ;   - see timeline ops above
  33 ;   - see hashtag and channels above
  34 ; - d | download
  35 ; - u | upload
  36 ;   - calls user-configured command to upload user's own feed file to their server
  37
  38 #lang racket
  39
  40 (require racket/date)
  41
  42 (require http-client)
  43 (require rfc3339-old)
  44
  45 (struct msg  (ts_epoch ts_rfc3339 nick uri text))
  46 (struct feed (nick uri))
  47
  48 (define (concurrent-filter-map num_workers f xs)
  49   ; TODO switch from mailboxes to channels
  50   (define (make-worker id f)
  51     (define parent (current-thread))
  52     (λ ()
  53        (define self (current-thread))
  54        (define (work)
  55          (thread-send parent (cons 'next self))
  56          (match (thread-receive)
  57            ['done          (thread-send parent (cons 'exit id))]
  58            [(cons 'unit x) (begin
  59                              (define y (f x))
  60                              (when y (thread-send parent (cons 'result y)))
  61                              (work))]))
  62        (work)))
  63   (define (dispatch ws xs ys)
  64     (if (empty? ws)
  65       ys
  66       (match (thread-receive)
  67         [(cons 'exit w)   (dispatch (remove w ws =) xs ys)]
  68         [(cons 'result y) (dispatch ws xs (cons y ys))]
  69         [(cons 'next thd) (match xs
  70                             ['()         (begin
  71                                            (thread-send thd 'done)
  72                                            (dispatch ws xs ys))]
  73                             [(cons x xs) (begin
  74                                            (thread-send thd (cons 'unit x))
  75                                            (dispatch ws xs ys))])])))
  76   (define workers (range num_workers))
  77   (define threads (map (λ (id) (thread (make-worker id f))) workers))
  78   (define results (dispatch workers xs '()))
  79   (for-each thread-wait threads)
  80   results)
  81
  82 (define (msg-print out-format odd msg)
  83   (printf
  84     (match out-format
  85       ['single-line "~a  \033[1;37m<~a ~a>\033[0m  \033[0;~am~a\033[0m~n"]
  86       ['multi-line  "~a~n\033[1;37m<~a ~a>\033[0m~n\033[0;~am~a\033[0m~n~n"]
  87       [_           (raise (format "Invalid output format: ~a" out-format))])
  88     (date->string (seconds->date [msg-ts_epoch msg]) #t)
  89     (msg-nick msg)
  90     (msg-uri  msg)
  91     (if odd 36 33)
  92     (msg-text msg)))
  93
  94 (define re-msg-begin
  95   ; TODO Zulu offset. Maybe in several formats. Which ones?
  96   (pregexp "^[0-9]{4}-[0-9]{2}-[0-9]{2}T[0-9]{2}:[0-9]{2}:[0-9]{2}"))
  97
  98 (define (str->msg nick uri str)
  99   (if (not (regexp-match? re-msg-begin str))
 100     (begin
 101       (log-debug "Non-msg line from nick:~a, line:~a" nick str)
 102       #f)
 103     (let ([toks (string-split str (regexp "\t+"))])
 104       (if (not (= 2 (length toks)))
 105         (begin
 106           (log-warning "Invalid msg line from nick:~a, msg:~a" nick str)
 107           #f)
 108         (let*
 109           ([ts_rfc3339 (first  toks)]
 110            [text       (second toks)]
 111            [t          (string->rfc3339-record ts_rfc3339)]
 112            ; TODO handle tz offset
 113            [ts_epoch (find-seconds [rfc3339-record:second t]
 114                                    [rfc3339-record:minute t]
 115                                    [rfc3339-record:hour   t]
 116                                    [rfc3339-record:mday   t]
 117                                    [rfc3339-record:month  t]
 118                                    [rfc3339-record:year   t])])
 119           (msg ts_epoch ts_rfc3339 nick uri text))))))
 120
 121 (define (str->lines str)
 122   (string-split str (regexp "[\r\n]+")))
 123
 124 (define (str->msgs nick uri str)
 125   (filter-map (λ (line) (str->msg nick uri line)) (str->lines str)))
 126
 127 (define (uri-fetch uri)
 128   (log-info "GET ~a" uri)
 129   (define resp (http-get uri))
 130   (define status (http-response-code resp))
 131   (define body (http-response-body resp))
 132   (log-debug "finished GET ~a status:~a  body length:~a"
 133              uri status (string-length body))
 134   ; TODO Handle redirects
 135   (if (= status 200) body (raise status)))
 136
 137 (define (timeline-print out-format timeline)
 138   (for ([msg timeline]
 139         [i   (in-naturals)])
 140     (msg-print out-format (odd? i) msg)))
 141
 142 (define (feed->msgs feed)
 143   (log-info "downloading feed nick:~a uri:~a"
 144             (feed-nick feed)
 145             (feed-uri feed))
 146   (with-handlers
 147     ([exn:fail:network?
 148        (λ (e)
 149           (log-error "network error nick:~a uri:~a  exn:~a"
 150                      (feed-nick feed)
 151                      (feed-uri feed)
 152                      e)
 153           #f)]
 154      [integer?
 155        (λ (status)
 156           (log-error "http error nick:~a uri:~a  status:~a"
 157                      (feed-nick feed)
 158                      (feed-uri feed)
 159                      status)
 160           #f)])
 161     (define uri (feed-uri feed))
 162     (str->msgs [feed-nick feed] uri [uri-fetch uri])))
 163
 164 ; TODO timeline contract : time-sorted list of messages
 165 (define (timeline num_workers feeds)
 166   (sort (append* (concurrent-filter-map num_workers feed->msgs feeds))
 167         (λ (a b) [< (msg-ts_epoch a) (msg-ts_epoch b)])))
 168
 169 (define (str->feed str)
 170   ; TODO validation
 171   (define toks (string-split str))
 172   (apply feed toks))
 173
 174 (define (str->feeds str)
 175   (map str->feed (str->lines str)))
 176
 177 (define (file->feeds filename)
 178   (str->feeds (file->string filename)))
 179
 180 (define (we-are-twtxt)
 181   (define uri
 182     "https://raw.githubusercontent.com/mdom/we-are-twtxt/master/we-are-twtxt.txt")
 183   (str->feeds (uri-fetch uri)))
 184
 185 (define (setup-logging)
 186   (define logger (make-logger #f #f 'debug #f))
 187   (define log-chan (make-log-receiver logger 'debug))
 188   (void (thread (λ ()
 189                    [date-display-format 'iso-8601]
 190                    [let loop ()
 191                      (define data  (sync log-chan))
 192                      (define level (vector-ref data 0))
 193                      (define msg   (vector-ref data 1))
 194                      (define ts    (date->string (current-date) #t))
 195                      (eprintf "~a [~a] ~a~n" ts level msg)
 196                      (loop)])))
 197   (current-logger logger))
 198
 199 (define (main)
 200   (define user-agent
 201     (let*
 202       ([prog-name      "tt"]
 203        [prog-version   "0.3.3"]
 204        [prog-uri       "https://github.com/xandkar/tt"]
 205        [user-feed-file (expand-user-path "~/twtxt-me.txt")]
 206        [user
 207          (if (file-exists? user-feed-file)
 208            (let ([user (first (file->feeds user-feed-file))])
 209              (format "+~a; @~a" (feed-uri user) (feed-nick user)))
 210            (format "+~a" prog-uri))]
 211        )
 212       (format "~a/~a (~a)" prog-name prog-version user)))
 213
 214   (setup-logging)
 215   (current-http-response-auto #f)
 216   (current-http-user-agent user-agent)
 217   (date-display-format 'rfc2822)
 218
 219   (define args (current-command-line-arguments))
 220   (define feeds
 221     (if (vector-empty? args)
 222       (we-are-twtxt)
 223       (file->feeds (vector-ref args 0))))
 224   (define out-format 'multi-line)
 225   (define num_workers 15) ; 15 was fastest out of the tried 1, 5, 10, 15 and 20.
 226   (timeline-print out-format (timeline num_workers feeds)))
 227
 228 (main)