Commit | Line | Data |
---|---|---|
cd541405 | 1 | #lang typed/racket/no-check |
4764ff89 | 2 | |
1d753430 | 3 | (require openssl/sha1) |
4764ff89 | 4 | (require racket/date) |
9c464d95 SK |
5 | (require |
6 | net/http-client | |
edadb804 | 7 | net/uri-codec |
9c464d95 SK |
8 | net/url-string |
9 | net/url-structs) | |
4764ff89 | 10 | |
3c9c8266 SK |
11 | (require (prefix-in info: "info.rkt")) |
12 | ||
78398948 | 13 | (module+ test |
de3ff448 | 14 | (require rackunit)) |
78398948 | 15 | |
98529d3d SK |
16 | (define-type Url |
17 | net/url-structs:url) | |
18 | ||
19 | (define-type Out-Format | |
20 | (U 'single-line | |
21 | 'multi-line)) | |
22 | ||
23 | (define-type Timeline-Order | |
24 | (U 'old->new | |
25 | 'new->old)) | |
26 | ||
b0ff061a | 27 | (struct Msg |
78142acb | 28 | ([ts-epoch : Integer] |
3877a0c4 | 29 | [ts-orig : String] |
13c11724 | 30 | [nick : (Option String)] |
98529d3d | 31 | [uri : Url] |
13c11724 | 32 | [text : String] |
b0ff061a | 33 | [mentions : (Listof Peer)])) |
9c464d95 | 34 | |
dbc26280 | 35 | (struct Peer |
13c11724 | 36 | ([nick : (Option String)] |
d0a0e073 SK |
37 | [uri : Url]) |
38 | #:transparent) | |
4764ff89 | 39 | |
edadb804 SK |
40 | (: tt-home-dir Path-String) |
41 | (define tt-home-dir (build-path (expand-user-path "~") ".tt")) | |
42 | ||
9a346534 | 43 | (: concurrent-filter-map (∀ (α β) (-> Natural (-> α β) (Listof α) (Listof β)))) |
78142acb | 44 | (define (concurrent-filter-map num-workers f xs) |
dad4504d | 45 | ; TODO preserve order of elements OR communicate that reorder is expected |
a239a233 | 46 | ; TODO switch from mailboxes to channels |
895a32cf SK |
47 | (define (make-worker id f) |
48 | (define parent (current-thread)) | |
49 | (λ () | |
a9511f7c SK |
50 | (define self : Thread (current-thread)) |
51 | (: work (∀ (α) (-> α))) | |
895a32cf SK |
52 | (define (work) |
53 | (thread-send parent (cons 'next self)) | |
54 | (match (thread-receive) | |
c562bea3 SK |
55 | ['done (thread-send parent (cons 'exit id))] |
56 | [(cons 'unit x) (begin | |
57 | (define y (f x)) | |
58 | (when y (thread-send parent (cons 'result y))) | |
59 | (work))])) | |
895a32cf | 60 | (work))) |
a9511f7c | 61 | (: dispatch (∀ (α β) (-> (Listof Nonnegative-Integer) (Listof α) (Listof β)))) |
895a32cf SK |
62 | (define (dispatch ws xs ys) |
63 | (if (empty? ws) | |
f1493e49 SK |
64 | ys |
65 | (match (thread-receive) | |
c562bea3 SK |
66 | [(cons 'exit w) (dispatch (remove w ws =) xs ys)] |
67 | [(cons 'result y) (dispatch ws xs (cons y ys))] | |
68 | [(cons 'next thd) (match xs | |
69 | ['() (begin | |
70 | (thread-send thd 'done) | |
71 | (dispatch ws xs ys))] | |
72 | [(cons x xs) (begin | |
73 | (thread-send thd (cons 'unit x)) | |
74 | (dispatch ws xs ys))])]))) | |
78142acb | 75 | (define workers (range num-workers)) |
9926c9a9 SK |
76 | (define threads (map (λ (id) (thread (make-worker id f))) workers)) |
77 | (define results (dispatch workers xs '())) | |
895a32cf SK |
78 | (for-each thread-wait threads) |
79 | results) | |
80 | ||
dad4504d | 81 | (module+ test |
de3ff448 SK |
82 | (let* ([f (λ (x) (if (even? x) x #f))] |
83 | [xs (range 11)] | |
84 | [actual (sort (concurrent-filter-map 10 f xs) <)] | |
85 | [expected (sort ( filter-map f xs) <)]) | |
c562bea3 | 86 | (check-equal? actual expected "concurrent-filter-map"))) |
dad4504d | 87 | |
98529d3d | 88 | (: msg-print (-> Out-Format Integer Msg Void)) |
3d042e75 SK |
89 | (define msg-print |
90 | (let* ([colors (vector 36 33)] | |
91 | [n (vector-length colors)]) | |
92 | (λ (out-format color-i msg) | |
01e4c499 | 93 | (let ([color (vector-ref colors (modulo color-i n))] |
b0ff061a SK |
94 | [nick (Msg-nick msg)] |
95 | [uri (url->string (Msg-uri msg))] | |
96 | [text (Msg-text msg)] | |
97 | [mentions (Msg-mentions msg)]) | |
3d042e75 | 98 | (match out-format |
01e4c499 | 99 | ['single-line |
13c11724 SK |
100 | (let ([nick (if nick nick uri)]) |
101 | (printf "~a \033[1;37m<~a>\033[0m \033[0;~am~a\033[0m~n" | |
102 | (parameterize | |
103 | ([date-display-format 'iso-8601]) | |
b0ff061a | 104 | (date->string (seconds->date (Msg-ts-epoch msg)) #t)) |
13c11724 | 105 | nick color text))] |
01e4c499 | 106 | ['multi-line |
13c11724 SK |
107 | (let ([nick (if nick (string-append nick " ") "")]) |
108 | (printf "~a (~a)~n\033[1;37m<~a~a>\033[0m~n\033[0;~am~a\033[0m~n~n" | |
109 | (parameterize | |
110 | ([date-display-format 'rfc2822]) | |
b0ff061a SK |
111 | (date->string (seconds->date (Msg-ts-epoch msg)) #t)) |
112 | (Msg-ts-orig msg) | |
13c11724 | 113 | nick uri color text))]))))) |
e96264cc | 114 | |
3877a0c4 SK |
115 | (: rfc3339->epoch (-> String (Option Nonnegative-Integer))) |
116 | (define rfc3339->epoch | |
117 | (let ([re (pregexp "^([0-9]{4})-([0-9]{2})-([0-9]{2})T([0-9]{2}):([0-9]{2})(:([0-9]{2}))?(\\.[0-9]+)?(Z|([+-])([0-9]{1,2}):?([0-9]{2}))?$")]) | |
118 | (λ (ts) | |
119 | (match (regexp-match re ts) | |
120 | [(list _wholething yyyy mm dd HH MM _:SS SS _fractional tz-whole tz-sign tz-HH tz-MM) | |
121 | (let* | |
122 | ([tz-offset | |
123 | (match* (tz-whole tz-sign tz-HH tz-MM) | |
124 | [("Z" #f #f #f) | |
125 | 0] | |
126 | [(_ (or "-" "+") (? identity h) (? identity m)) | |
127 | (let ([h (string->number h)] | |
128 | [m (string->number m)] | |
129 | ; Reverse to get back to UTC: | |
130 | [op (match tz-sign ["+" -] ["-" +])]) | |
131 | (op 0 (+ (* 60 m) (* 60 (* 60 h)))))] | |
132 | [(a b c d) | |
133 | (log-warning "Impossible TZ string: ~v, components: ~v ~v ~v ~v" tz-whole a b c d) | |
134 | 0])] | |
135 | [ts-orig ts] | |
136 | [local-time? #f] | |
137 | [ts-epoch (find-seconds (if SS (string->number SS) 0) | |
138 | (string->number MM) | |
139 | (string->number HH) | |
140 | (string->number dd) | |
141 | (string->number mm) | |
142 | (string->number yyyy) | |
143 | local-time?)]) | |
144 | (+ ts-epoch tz-offset))] | |
145 | [_ | |
146 | (log-error "Invalid timestamp: ~v" ts) | |
147 | #f])))) | |
148 | ||
13c11724 | 149 | (: str->msg (-> (Option String) Url String (Option Msg))) |
b4689464 | 150 | (define str->msg |
3877a0c4 | 151 | (let ([re (pregexp "^([^\\s\t]+)[\\s\t]+(.*)$")]) |
b4689464 SK |
152 | (λ (nick uri str) |
153 | (with-handlers* | |
154 | ([exn:fail? | |
155 | (λ (e) | |
9c464d95 SK |
156 | (log-error |
157 | "Failed to parse msg: ~v, from: ~v, at: ~v, because: ~v" | |
158 | str nick (url->string uri) e) | |
b4689464 SK |
159 | #f)]) |
160 | (match (regexp-match re str) | |
3877a0c4 SK |
161 | [(list _wholething ts-orig text) |
162 | (let ([ts-epoch (rfc3339->epoch ts-orig)]) | |
163 | (if ts-epoch | |
13c11724 SK |
164 | (let ([mentions |
165 | (filter-map | |
166 | (λ (m) (match (regexp-match #px"@<([^>]+)>" m) | |
167 | [(list _wholething nick-uri) | |
dbc26280 | 168 | (str->peer nick-uri)])) |
13c11724 | 169 | (regexp-match* #px"@<[^\\s]+([\\s]+)?[^>]+>" text))]) |
b0ff061a | 170 | (Msg ts-epoch ts-orig nick uri text mentions)) |
3877a0c4 SK |
171 | (begin |
172 | (log-error | |
173 | "Msg rejected due to invalid timestamp: ~v, nick:~v, uri:~v" | |
174 | str nick (url->string uri)) | |
175 | #f)))] | |
b4689464 | 176 | [_ |
13c11724 | 177 | (log-debug "Non-msg line from nick:~v, line:~a" nick str) |
b4689464 | 178 | #f]))))) |
88d50b3e | 179 | |
63afa259 | 180 | (module+ test |
13c11724 | 181 | ; TODO Test for when missing-nick case |
b4689464 SK |
182 | (let* ([tzs (for*/list ([d '("-" "+")] |
183 | [h '("5" "05")] | |
184 | [m '("00" ":00" "57" ":57")]) | |
185 | (string-append d h m))] | |
186 | [tzs (list* "" "Z" tzs)]) | |
187 | (for* ([n '("fake-nick")] | |
188 | [u '("fake-uri")] | |
189 | [s '("" ":10")] | |
190 | [f '("" ".1337")] | |
191 | [z tzs] | |
192 | [sep (list "\t" " ")] | |
193 | [txt '("foo bar baz" "'jaz poop bear giraffe / tea" "@*\"``")]) | |
194 | (let* ([ts (string-append "2020-11-18T22:22" | |
195 | (if (non-empty-string? s) s ":00") | |
196 | z)] | |
197 | [m (str->msg n u (string-append ts sep txt))]) | |
198 | (check-not-false m) | |
b0ff061a SK |
199 | (check-equal? (Msg-nick m) n) |
200 | (check-equal? (Msg-uri m) u) | |
201 | (check-equal? (Msg-text m) txt) | |
202 | (check-equal? (Msg-ts-orig m) ts (format "Given: ~v" ts)) | |
b4689464 SK |
203 | ))) |
204 | ||
de3ff448 SK |
205 | (let* ([ts "2020-11-18T22:22:09-0500"] |
206 | [tab " "] | |
207 | [text "Lorem ipsum"] | |
208 | [nick "foo"] | |
209 | [uri "bar"] | |
210 | [actual (str->msg nick uri (string-append ts tab text))] | |
b0ff061a | 211 | [expected (Msg 1605756129 ts nick uri text)]) |
c562bea3 | 212 | (check-equal? |
b0ff061a SK |
213 | (Msg-ts-epoch actual) |
214 | (Msg-ts-epoch expected) | |
78142acb | 215 | "str->msg ts-epoch") |
3877a0c4 | 216 | (check-equal? |
b0ff061a SK |
217 | (Msg-ts-orig actual) |
218 | (Msg-ts-orig expected) | |
3877a0c4 | 219 | "str->msg ts-orig") |
c562bea3 | 220 | (check-equal? |
b0ff061a SK |
221 | (Msg-nick actual) |
222 | (Msg-nick expected) | |
c562bea3 SK |
223 | "str->msg nick") |
224 | (check-equal? | |
b0ff061a SK |
225 | (Msg-uri actual) |
226 | (Msg-uri expected) | |
c562bea3 SK |
227 | "str->msg uri") |
228 | (check-equal? | |
b0ff061a SK |
229 | (Msg-text actual) |
230 | (Msg-text expected) | |
c562bea3 | 231 | "str->msg text"))) |
63afa259 | 232 | |
98529d3d | 233 | (: str->lines (-> String (Listof String))) |
e96264cc SK |
234 | (define (str->lines str) |
235 | (string-split str (regexp "[\r\n]+"))) | |
236 | ||
63afa259 | 237 | (module+ test |
de3ff448 | 238 | (check-equal? (str->lines "abc\ndef\n\nghi") '("abc" "def" "ghi"))) |
63afa259 | 239 | |
13c11724 | 240 | (: str->msgs (-> (Option String) Url String (Listof Msg))) |
b201e854 | 241 | (define (str->msgs nick uri str) |
3877a0c4 | 242 | (filter-map (λ (line) (str->msg nick uri line)) (filter-comments (str->lines str)))) |
4764ff89 | 243 | |
edadb804 SK |
244 | (: cache-dir Path-String) |
245 | (define cache-dir (build-path tt-home-dir "cache")) | |
246 | ||
247 | (: url->cache-file-path-v1 (-> Url Path-String)) | |
248 | (define (url->cache-file-path-v1 uri) | |
249 | (define (hash-sha1 str) : (-> String String) | |
250 | (define in (open-input-string str)) | |
251 | (define digest (sha1 in)) | |
252 | (close-input-port in) | |
253 | digest) | |
254 | (build-path cache-dir (hash-sha1 (url->string uri)))) | |
255 | ||
256 | (: url->cache-file-path-v2 (-> Url Path-String)) | |
257 | (define (url->cache-file-path-v2 uri) | |
258 | (build-path cache-dir (uri-encode (url->string uri)))) | |
1d753430 | 259 | |
edadb804 | 260 | (define url->cache-file-path url->cache-file-path-v2) |
9c464d95 | 261 | |
98529d3d SK |
262 | ; TODO Return Option |
263 | (: uri-read-cached (-> Url String)) | |
4214c0f3 | 264 | (define (uri-read-cached uri) |
edadb804 SK |
265 | (define path-v1 (url->cache-file-path-v1 uri)) |
266 | (define path-v2 (url->cache-file-path-v2 uri)) | |
267 | (when (file-exists? path-v1) | |
268 | (rename-file-or-directory path-v1 path-v2 #t)) | |
269 | (if (file-exists? path-v2) | |
270 | (file->string path-v2) | |
0e16a46c | 271 | (begin |
9c464d95 | 272 | (log-warning "Cache file not found for URI: ~a" (url->string uri)) |
4214c0f3 SK |
273 | ""))) |
274 | ||
dbc26280 SK |
275 | (: str->peer (String (Option Peer))) |
276 | (define (str->peer str) | |
277 | (log-debug "Parsing peer string: ~v" str) | |
13c11724 SK |
278 | (with-handlers* |
279 | ([exn:fail? | |
280 | (λ (e) | |
281 | (log-error "Invalid URI in string: ~v, exn: ~v" str e) | |
282 | #f)]) | |
283 | (match (string-split str) | |
dbc26280 SK |
284 | [(list u) (Peer #f (string->url u))] |
285 | [(list n u) (Peer n (string->url u))] | |
13c11724 | 286 | [_ |
dbc26280 | 287 | (log-error "Invalid peer string: ~v" str) |
13c11724 SK |
288 | #f]))) |
289 | ||
9c464d95 | 290 | |
98529d3d | 291 | (: filter-comments (-> (Listof String) (Listof String))) |
9c464d95 SK |
292 | (define (filter-comments lines) |
293 | (filter-not (λ (line) (string-prefix? line "#")) lines)) | |
294 | ||
dbc26280 SK |
295 | (: str->peers (-> String (Listof Peer))) |
296 | (define (str->peers str) | |
297 | (filter-map str->peer (filter-comments (str->lines str)))) | |
9c464d95 | 298 | |
dbc26280 | 299 | (: file->peers (-> Path-String (Listof Peer))) |
d0a0e073 SK |
300 | (define (file->peers file-path) |
301 | (if (file-exists? file-path) | |
302 | (str->peers (file->string file-path)) | |
303 | (begin | |
304 | (log-error "File does not exist: ~v" (path->string file-path)) | |
305 | '()))) | |
9c464d95 | 306 | |
98529d3d | 307 | (: user-agent String) |
9c464d95 SK |
308 | (define user-agent |
309 | (let* | |
310 | ([prog-name "tt"] | |
3c9c8266 | 311 | [prog-version (info:#%info-lookup 'version)] |
9c464d95 | 312 | [prog-uri "https://github.com/xandkar/tt"] |
dbc26280 | 313 | [user-peer-file (build-path tt-home-dir "me")] |
9c464d95 | 314 | [user |
dbc26280 SK |
315 | (if (file-exists? user-peer-file) |
316 | (match (first (file->peers user-peer-file)) | |
317 | [(Peer #f u) (format "+~a" (url->string u) )] | |
318 | [(Peer n u) (format "+~a; @~a" (url->string u) n)]) | |
9c464d95 SK |
319 | (format "+~a" prog-uri))]) |
320 | (format "~a/~a (~a)" prog-name prog-version user))) | |
321 | ||
98529d3d | 322 | (: uri-download (-> Url Void)) |
9c464d95 SK |
323 | (define (uri-download u) |
324 | (define cache-file-path (url->cache-file-path u)) | |
325 | (log-debug "uri-download ~v into ~v" u cache-file-path) | |
326 | (match* ((url-scheme u) (url-host u) (url-port u)) | |
327 | [(s h p) | |
328 | #:when (and s h) | |
329 | (define ssl? (string=? s "https")) | |
330 | (define-values (status-line headers body-input) | |
331 | ; TODO Timeout. Currently hangs on slow connections. | |
332 | (http-sendrecv | |
333 | h | |
334 | (url->string (struct-copy url u [scheme #f] [host #f])) | |
335 | #:ssl? ssl? | |
336 | #:port (cond [p p] [ssl? 443] [else 80]) | |
337 | #:headers (list (format "User-Agent: ~a" user-agent)) | |
338 | )) | |
339 | (log-debug "headers: ~v" headers) | |
340 | (log-debug "status-line: ~v" status-line) | |
341 | (define status | |
342 | (string->number (second (string-split (bytes->string/utf-8 status-line))))) | |
343 | (log-debug "status: ~v" status) | |
344 | ; TODO Handle redirects | |
345 | (if (= 200 status) | |
edadb804 SK |
346 | (begin |
347 | (make-parent-directory* cache-file-path) | |
348 | (call-with-output-file cache-file-path | |
349 | (curry copy-port body-input) | |
350 | #:exists 'replace)) | |
9c464d95 SK |
351 | (raise status))] |
352 | [(_ _ _) | |
353 | (log-error "Invalid URI: ~v" u)])) | |
4764ff89 | 354 | |
98529d3d | 355 | (: timeline-print (-> Out-Format (Listof Msg) Void)) |
b201e854 | 356 | (define (timeline-print out-format timeline) |
3d042e75 | 357 | (void (foldl (match-lambda** |
b0ff061a | 358 | [((and m (Msg _ _ nick _ _ _)) (cons prev-nick i)) |
13c11724 | 359 | (let ([i (if (equal? prev-nick nick) i (+ 1 i))]) |
3d042e75 SK |
360 | (msg-print out-format i m) |
361 | (cons nick i))]) | |
362 | (cons "" 0) | |
363 | timeline))) | |
4764ff89 | 364 | |
dbc26280 SK |
365 | (: peer->msgs (-> Peer (Listof Msg))) |
366 | (define (peer->msgs f) | |
367 | (match-define (Peer nick uri) f) | |
368 | (log-info "Reading peer nick:~v uri:~v" nick (url->string uri)) | |
9c464d95 | 369 | (str->msgs nick uri (uri-read-cached uri))) |
4214c0f3 | 370 | |
dbc26280 SK |
371 | (: peer-download (-> Peer Void)) |
372 | (define (peer-download f) | |
373 | (match-define (Peer nick uri) f) | |
2db1b40f | 374 | (define u (url->string uri)) |
dbc26280 | 375 | (log-info "Downloading peer uri:~a" u) |
9a6a9f9a | 376 | (with-handlers |
9c464d95 | 377 | ([exn:fail? |
9a6a9f9a | 378 | (λ (e) |
13c11724 | 379 | (log-error "Network error nick:~v uri:~v exn:~v" nick u e) |
9a6a9f9a SK |
380 | #f)] |
381 | [integer? | |
382 | (λ (status) | |
13c11724 | 383 | (log-error "HTTP error nick:~v uri:~a status:~a" nick u status) |
9a6a9f9a | 384 | #f)]) |
2db1b40f SK |
385 | (define-values (_result _tm-cpu-ms tm-real-ms _tm-gc-ms) |
386 | (time-apply uri-download (list uri))) | |
dbc26280 | 387 | (log-info "Peer downloaded in ~a seconds, uri: ~a" (/ tm-real-ms 1000.0) u))) |
4214c0f3 | 388 | |
dbc26280 SK |
389 | (: timeline-download (-> Integer (Listof Peer) Void)) |
390 | (define (timeline-download num-workers peers) | |
4214c0f3 | 391 | ; TODO No need for map - can just iter |
dbc26280 | 392 | (void (concurrent-filter-map num-workers peer-download peers))) |
9a6a9f9a SK |
393 | |
394 | ; TODO timeline contract : time-sorted list of messages | |
dbc26280 SK |
395 | (: timeline-read (-> Timeline-Order (Listof Peer) (Listof Msg))) |
396 | (define (timeline-read order peers) | |
a4899240 SK |
397 | (define cmp (match order |
398 | ['old->new <] | |
399 | ['new->old >])) | |
dbc26280 | 400 | (sort (append* (filter-map peer->msgs peers)) |
b0ff061a | 401 | (λ (a b) (cmp (Msg-ts-epoch a) (Msg-ts-epoch b))))) |
4764ff89 | 402 | |
d0a0e073 SK |
403 | (: paths->peers (-> (Listof String) (Listof Peer))) |
404 | (define (paths->peers paths) | |
405 | (let* ([paths (match paths | |
406 | ['() | |
407 | (let ([peer-refs-file (build-path tt-home-dir "peers")]) | |
408 | (log-debug | |
409 | "No peer ref file paths provided, defaulting to ~v" | |
410 | (path->string peer-refs-file)) | |
411 | (list peer-refs-file))] | |
412 | [paths | |
413 | (log-debug "Peer ref file paths provided: ~v" paths) | |
414 | (map string->path paths)])] | |
415 | [peers (append* (map file->peers paths))]) | |
416 | (log-info "Read-in ~a peers." (length peers)) | |
417 | peers)) | |
418 | ||
56de6228 SK |
419 | (: log-writer-stop (-> Thread Void)) |
420 | (define (log-writer-stop log-writer) | |
421 | (log-message (current-logger) 'fatal 'stop "Exiting." #f) | |
422 | (thread-wait log-writer)) | |
423 | ||
0d3f753c SK |
424 | (: log-writer-start (-> Log-Level Thread)) |
425 | (define (log-writer-start level) | |
56de6228 SK |
426 | (let* ([logger |
427 | (make-logger #f #f level #f)] | |
428 | [log-receiver | |
429 | (make-log-receiver logger level)] | |
430 | [log-writer | |
431 | (thread | |
432 | (λ () | |
433 | (parameterize | |
434 | ([date-display-format 'iso-8601]) | |
435 | (let loop () | |
436 | (match-define (vector level msg _ topic) (sync log-receiver)) | |
437 | (unless (equal? topic 'stop) | |
438 | (eprintf "~a [~a] ~a~n" (date->string (current-date) #t) level msg) | |
439 | (loop))))))]) | |
440 | (current-logger logger) | |
441 | log-writer)) | |
01e4c499 | 442 | |
24c6a76b | 443 | (module+ main |
24f1f64b | 444 | (let ([log-level 'info]) |
c562bea3 | 445 | (command-line |
24f1f64b SK |
446 | #:program |
447 | "tt" | |
c562bea3 | 448 | #:once-each |
01e4c499 SK |
449 | [("-d" "--debug") |
450 | "Enable debug log level." | |
451 | (set! log-level 'debug)] | |
24f1f64b SK |
452 | #:help-labels |
453 | "" | |
454 | "and <command> is one of" | |
4214c0f3 SK |
455 | "r, read i : Read the timeline." |
456 | "d, download : Download the timeline." | |
edadb804 | 457 | ; TODO Add path dynamically |
3a4b2233 | 458 | "u, upload : Upload your twtxt file (alias to execute ~/.tt/upload)." |
24f1f64b SK |
459 | "" |
460 | #:args (command . args) | |
0d3f753c | 461 | (define log-writer (log-writer-start log-level)) |
4214c0f3 | 462 | (current-command-line-arguments (list->vector args)) |
24f1f64b | 463 | (match command |
4214c0f3 | 464 | [(or "d" "download") |
2db1b40f | 465 | ; Initially, 15 was fastest out of the tried: 1, 5, 10, 20. Then I |
edadb804 | 466 | ; started noticing significant slowdowns. Reducing to 5 seems to help. |
2db1b40f | 467 | (let ([num-workers 5]) |
24f1f64b SK |
468 | (command-line |
469 | #:program | |
4214c0f3 | 470 | "tt download" |
24f1f64b SK |
471 | #:once-each |
472 | [("-j" "--jobs") | |
473 | njobs "Number of concurrent jobs." | |
78142acb | 474 | (set! num-workers (string->number njobs))] |
d0a0e073 | 475 | #:args file-paths |
32dcc0b0 | 476 | (define-values (_res _cpu real-ms _gc) |
d0a0e073 | 477 | (time-apply timeline-download (list num-workers (paths->peers file-paths)))) |
0d3f753c | 478 | (log-info "Timeline downloaded in ~a seconds." (/ real-ms 1000.0))))] |
3a4b2233 SK |
479 | [(or "u" "upload") |
480 | (command-line | |
3877a0c4 SK |
481 | #:program |
482 | "tt upload" | |
483 | #:args () | |
edadb804 | 484 | (if (system (path->string (build-path tt-home-dir "upload"))) |
3a4b2233 SK |
485 | (exit 0) |
486 | (exit 1)))] | |
4214c0f3 | 487 | [(or "r" "read") |
a4899240 SK |
488 | (let ([out-format 'multi-line] |
489 | [order 'old->new]) | |
4214c0f3 SK |
490 | (command-line |
491 | #:program | |
492 | "tt read" | |
a4899240 SK |
493 | #:once-each |
494 | [("-r" "--rev") | |
495 | "Reverse displayed timeline order." | |
496 | (set! order 'new->old)] | |
24f1f64b SK |
497 | #:once-any |
498 | [("-s" "--short") | |
499 | "Short output format" | |
500 | (set! out-format 'single-line)] | |
501 | [("-l" "--long") | |
502 | "Long output format" | |
503 | (set! out-format 'multi-line)] | |
d0a0e073 SK |
504 | #:args file-paths |
505 | (timeline-print out-format (timeline-read order (paths->peers file-paths)))))]) | |
0d3f753c | 506 | (log-writer-stop log-writer)))) |